/[pcre]/code/trunk/configure.ac
ViewVC logotype

Contents of /code/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 487 - (show annotations) (download)
Wed Jan 6 10:26:55 2010 UTC (4 years, 3 months ago) by ph10
File size: 27780 byte(s)
Tidying updates for 8.01-RC1 release.

1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl NOTE FOR MAINTAINERS: Do not use minor version numbers 08 or 09 because
4 dnl the leading zeros may cause them to be treated as invalid octal constants
5 dnl if a PCRE user writes code that uses PCRE_MINOR as a number. There is now
6 dnl a check further down that throws an error if 08 or 09 are used.
7
8 dnl The PCRE_PRERELEASE feature is for identifying release candidates. It might
9 dnl be defined as -RC2, for example. For real releases, it should be empty.
10
11 m4_define(pcre_major, [8])
12 m4_define(pcre_minor, [01])
13 m4_define(pcre_prerelease, [-RC1])
14 m4_define(pcre_date, [2010-01-06])
15
16 # Libtool shared library interface versions (current:revision:age)
17 m4_define(libpcre_version, [0:1:0])
18 m4_define(libpcreposix_version, [0:0:0])
19 m4_define(libpcrecpp_version, [0:0:0])
20
21 AC_PREREQ(2.57)
22 AC_INIT(PCRE, pcre_major.pcre_minor[]pcre_prerelease, , pcre)
23 AC_CONFIG_SRCDIR([pcre.h.in])
24 AM_INIT_AUTOMAKE([dist-bzip2 dist-zip])
25 AC_CONFIG_HEADERS(config.h)
26
27 # This was added at the suggestion of libtoolize (03-Jan-10)
28 AC_CONFIG_MACRO_DIR([m4])
29
30 # The default CFLAGS and CXXFLAGS in Autoconf are "-g -O2" for gcc and just
31 # "-g" for any other compiler. There doesn't seem to be a standard way of
32 # getting rid of the -g (which I don't think is needed for a production
33 # library). This fudge seems to achieve the necessary. First, we remember the
34 # externally set values of CFLAGS and CXXFLAGS. Then call the AC_PROG_CC and
35 # AC_PROG_CXX macros to find the compilers - if CFLAGS and CXXFLAGS are not
36 # set, they will be set to Autoconf's defaults. Afterwards, if the original
37 # values were not set, remove the -g from the Autoconf defaults.
38 # (PH 02-May-07)
39
40 remember_set_CFLAGS="$CFLAGS"
41 remember_set_CXXFLAGS="$CXXFLAGS"
42
43 AC_PROG_CC
44 AC_PROG_CXX
45
46 if test "x$remember_set_CFLAGS" = "x"
47 then
48 if test "$CFLAGS" = "-g -O2"
49 then
50 CFLAGS="-O2"
51 elif test "$CFLAGS" = "-g"
52 then
53 CFLAGS=""
54 fi
55 fi
56
57 if test "x$remember_set_CXXFLAGS" = "x"
58 then
59 if test "$CXXFLAGS" = "-g -O2"
60 then
61 CXXFLAGS="-O2"
62 elif test "$CXXFLAGS" = "-g"
63 then
64 CXXFLAGS=""
65 fi
66 fi
67
68 # AC_PROG_CXX will return "g++" even if no c++ compiler is installed.
69 # Check for that case, and just disable c++ code if g++ doesn't run.
70 AC_LANG_PUSH(C++)
71 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[]),, CXX=""; CXXCP=""; CXXFLAGS="")
72 AC_LANG_POP
73
74 # Check for a 64-bit integer type
75 AC_TYPE_INT64_T
76
77 AC_PROG_INSTALL
78 AC_LIBTOOL_WIN32_DLL
79 AC_PROG_LIBTOOL
80 AC_PROG_LN_S
81
82 PCRE_MAJOR="pcre_major"
83 PCRE_MINOR="pcre_minor"
84 PCRE_PRERELEASE="pcre_prerelease"
85 PCRE_DATE="pcre_date"
86
87 if test "$PCRE_MINOR" = "08" -o "$PCRE_MINOR" = "09"
88 then
89 echo "***"
90 echo "*** Minor version number $PCRE_MINOR must not be used. ***"
91 echo "*** Use only 01 to 07 or 10 onwards, to avoid octal issues. ***"
92 echo "***"
93 exit 1
94 fi
95
96 AC_SUBST(PCRE_MAJOR)
97 AC_SUBST(PCRE_MINOR)
98 AC_SUBST(PCRE_PRERELEASE)
99 AC_SUBST(PCRE_DATE)
100
101 # Set a more sensible default value for $(htmldir).
102 if test "x$htmldir" = 'x${docdir}'
103 then
104 htmldir='${docdir}/html'
105 fi
106
107 # Handle --disable-cpp
108 AC_ARG_ENABLE(cpp,
109 AS_HELP_STRING([--disable-cpp],
110 [disable C++ support]),
111 , enable_cpp=yes)
112
113 # Handle --enable-rebuild-chartables
114 AC_ARG_ENABLE(rebuild-chartables,
115 AS_HELP_STRING([--enable-rebuild-chartables],
116 [rebuild character tables in current locale]),
117 , enable_rebuild_chartables=no)
118
119 # Handle --enable-utf8 (disabled by default)
120 AC_ARG_ENABLE(utf8,
121 AS_HELP_STRING([--enable-utf8],
122 [enable UTF-8 support (incompatible with --enable-ebcdic)]),
123 , enable_utf8=unset)
124
125 # Handle --enable-unicode-properties
126 AC_ARG_ENABLE(unicode-properties,
127 AS_HELP_STRING([--enable-unicode-properties],
128 [enable Unicode properties support (implies --enable-utf8)]),
129 , enable_unicode_properties=no)
130
131 # Handle --enable-newline=NL
132 dnl AC_ARG_ENABLE(newline,
133 dnl AS_HELP_STRING([--enable-newline=NL],
134 dnl [use NL as newline (lf, cr, crlf, anycrlf, any; default=lf)]),
135 dnl , enable_newline=lf)
136
137 # Separate newline options
138 ac_pcre_newline=lf
139 AC_ARG_ENABLE(newline-is-cr,
140 AS_HELP_STRING([--enable-newline-is-cr],
141 [use CR as newline character]),
142 ac_pcre_newline=cr)
143 AC_ARG_ENABLE(newline-is-lf,
144 AS_HELP_STRING([--enable-newline-is-lf],
145 [use LF as newline character (default)]),
146 ac_pcre_newline=lf)
147 AC_ARG_ENABLE(newline-is-crlf,
148 AS_HELP_STRING([--enable-newline-is-crlf],
149 [use CRLF as newline sequence]),
150 ac_pcre_newline=crlf)
151 AC_ARG_ENABLE(newline-is-anycrlf,
152 AS_HELP_STRING([--enable-newline-is-anycrlf],
153 [use CR, LF, or CRLF as newline sequence]),
154 ac_pcre_newline=anycrlf)
155 AC_ARG_ENABLE(newline-is-any,
156 AS_HELP_STRING([--enable-newline-is-any],
157 [use any valid Unicode newline sequence]),
158 ac_pcre_newline=any)
159 enable_newline="$ac_pcre_newline"
160
161 # Handle --enable-bsr-anycrlf
162 AC_ARG_ENABLE(bsr-anycrlf,
163 AS_HELP_STRING([--enable-bsr-anycrlf],
164 [\R matches only CR, LF, CRLF by default]),
165 , enable_bsr_anycrlf=no)
166
167 # Handle --enable-ebcdic
168 AC_ARG_ENABLE(ebcdic,
169 AS_HELP_STRING([--enable-ebcdic],
170 [assume EBCDIC coding rather than ASCII; incompatible with --enable-utf8; use only in (uncommon) EBCDIC environments; it implies --enable-rebuild-chartables]),
171 , enable_ebcdic=no)
172
173 # Handle --disable-stack-for-recursion
174 AC_ARG_ENABLE(stack-for-recursion,
175 AS_HELP_STRING([--disable-stack-for-recursion],
176 [don't use stack recursion when matching]),
177 , enable_stack_for_recursion=yes)
178
179 # Handle --enable-pcregrep-libz
180 AC_ARG_ENABLE(pcregrep-libz,
181 AS_HELP_STRING([--enable-pcregrep-libz],
182 [link pcregrep with libz to handle .gz files]),
183 , enable_pcregrep_libz=no)
184
185 # Handle --enable-pcregrep-libbz2
186 AC_ARG_ENABLE(pcregrep-libbz2,
187 AS_HELP_STRING([--enable-pcregrep-libbz2],
188 [link pcregrep with libbz2 to handle .bz2 files]),
189 , enable_pcregrep_libbz2=no)
190
191 # Handle --enable-pcretest-libreadline
192 AC_ARG_ENABLE(pcretest-libreadline,
193 AS_HELP_STRING([--enable-pcretest-libreadline],
194 [link pcretest with libreadline]),
195 , enable_pcretest_libreadline=no)
196
197 # Handle --with-posix-malloc-threshold=NBYTES
198 AC_ARG_WITH(posix-malloc-threshold,
199 AS_HELP_STRING([--with-posix-malloc-threshold=NBYTES],
200 [threshold for POSIX malloc usage (default=10)]),
201 , with_posix_malloc_threshold=10)
202
203 # Handle --with-link-size=N
204 AC_ARG_WITH(link-size,
205 AS_HELP_STRING([--with-link-size=N],
206 [internal link size (2, 3, or 4 allowed; default=2)]),
207 , with_link_size=2)
208
209 # Handle --with-match-limit=N
210 AC_ARG_WITH(match-limit,
211 AS_HELP_STRING([--with-match-limit=N],
212 [default limit on internal looping (default=10000000)]),
213 , with_match_limit=10000000)
214
215 # Handle --with-match-limit_recursion=N
216 #
217 # Note: In config.h, the default is to define MATCH_LIMIT_RECURSION
218 # symbolically as MATCH_LIMIT, which in turn is defined to be some numeric
219 # value (e.g. 10000000). MATCH_LIMIT_RECURSION can otherwise be set to some
220 # different numeric value (or even the same numeric value as MATCH_LIMIT,
221 # though no longer defined in terms of the latter).
222 #
223 AC_ARG_WITH(match-limit-recursion,
224 AS_HELP_STRING([--with-match-limit-recursion=N],
225 [default limit on internal recursion (default=MATCH_LIMIT)]),
226 , with_match_limit_recursion=MATCH_LIMIT)
227
228 # Make sure that if enable_unicode_properties was set, that UTF-8 support
229 # is enabled.
230 #
231 if test "x$enable_unicode_properties" = "xyes"
232 then
233 if test "x$enable_utf8" = "xno"
234 then
235 AC_MSG_ERROR([support for Unicode properties requires UTF-8 support])
236 fi
237 enable_utf8=yes
238 fi
239
240 if test "x$enable_utf8" = "xunset"
241 then
242 enable_utf8=no
243 fi
244
245 # Make sure that if enable_ebcdic is set, rebuild_chartables is also enabled.
246 # Also check that UTF-8 support is not requested, because PCRE cannot handle
247 # EBCDIC and UTF-8 in the same build. To do so it would need to use different
248 # character constants depending on the mode.
249 #
250 if test "x$enable_ebcdic" = "xyes"
251 then
252 enable_rebuild_chartables=yes
253 if test "x$enable_utf8" = "xyes"
254 then
255 AC_MSG_ERROR([support for EBCDIC and UTF-8 cannot be enabled at the same time])
256 fi
257 fi
258
259 # Convert the newline identifier into the appropriate integer value.
260 case "$enable_newline" in
261 lf) ac_pcre_newline_value=10 ;;
262 cr) ac_pcre_newline_value=13 ;;
263 crlf) ac_pcre_newline_value=3338 ;;
264 anycrlf) ac_pcre_newline_value=-2 ;;
265 any) ac_pcre_newline_value=-1 ;;
266 *)
267 AC_MSG_ERROR([invalid argument \"$enable_newline\" to --enable-newline option])
268 ;;
269 esac
270
271 # Check argument to --with-link-size
272 case "$with_link_size" in
273 2|3|4) ;;
274 *)
275 AC_MSG_ERROR([invalid argument \"$with_link_size\" to --with-link-size option])
276 ;;
277 esac
278
279 AH_TOP([
280 /* On Unix-like systems config.h.in is converted by "configure" into config.h.
281 Some other environments also support the use of "configure". PCRE is written in
282 Standard C, but there are a few non-standard things it can cope with, allowing
283 it to run on SunOS4 and other "close to standard" systems.
284
285 If you are going to build PCRE "by hand" on a system without "configure" you
286 should copy the distributed config.h.generic to config.h, and then set up the
287 macro definitions the way you need them. You must then add -DHAVE_CONFIG_H to
288 all of your compile commands, so that config.h is included at the start of
289 every source.
290
291 Alternatively, you can avoid editing by using -D on the compiler command line
292 to set the macro values. In this case, you do not have to set -DHAVE_CONFIG_H.
293
294 PCRE uses memmove() if HAVE_MEMMOVE is set to 1; otherwise it uses bcopy() if
295 HAVE_BCOPY is set to 1. If your system has neither bcopy() nor memmove(), set
296 them both to 0; an emulation function will be used. */])
297
298 # Checks for header files.
299 AC_HEADER_STDC
300 AC_CHECK_HEADERS(limits.h sys/types.h sys/stat.h dirent.h windows.h)
301
302 # The files below are C++ header files.
303 pcre_have_type_traits="0"
304 pcre_have_bits_type_traits="0"
305 if test "x$enable_cpp" = "xyes" -a -n "$CXX"
306 then
307 AC_LANG_PUSH(C++)
308
309 # Older versions of pcre defined pcrecpp::no_arg, but in new versions
310 # it's called pcrecpp::RE::no_arg. For backwards ABI compatibility,
311 # we want to make one an alias for the other. Different systems do
312 # this in different ways. Some systems, for instance, can do it via
313 # a linker flag: -alias (for os x 10.5) or -i (for os x <=10.4).
314 OLD_LDFLAGS="$LDFLAGS"
315 for flag in "-alias,__ZN7pcrecpp2RE6no_argE,__ZN7pcrecpp6no_argE" \
316 "-i__ZN7pcrecpp6no_argE:__ZN7pcrecpp2RE6no_argE"; do
317 AC_MSG_CHECKING([for alias support in the linker])
318 LDFLAGS="$OLD_LDFLAGS -Wl,$flag"
319 # We try to run the linker with this new ld flag. If the link fails,
320 # we give up and remove the new flag from LDFLAGS.
321 AC_LINK_IFELSE(AC_LANG_PROGRAM([namespace pcrecpp {
322 class RE { static int no_arg; };
323 int RE::no_arg;
324 }],
325 []),
326 [AC_MSG_RESULT([yes]);
327 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS -Wl,$flag";
328 break;],
329 AC_MSG_RESULT([no]))
330 done
331 LDFLAGS="$OLD_LDFLAGS"
332
333 # We could be more clever here, given we're doing AC_SUBST with this
334 # (eg set a var to be the name of the include file we want). But we're not
335 # so it's easy to change back to 'regular' autoconf vars if we needed to.
336 AC_CHECK_HEADERS(string, [pcre_have_cpp_headers="1"],
337 [pcre_have_cpp_headers="0"])
338 AC_CHECK_HEADERS(bits/type_traits.h, [pcre_have_bits_type_traits="1"],
339 [pcre_have_bits_type_traits="0"])
340 AC_CHECK_HEADERS(type_traits.h, [pcre_have_type_traits="1"],
341 [pcre_have_type_traits="0"])
342
343 # (This isn't c++-specific, but is only used in pcrecpp.cc, so try this
344 # in a c++ context. This matters becuase strtoimax is C99 and may not
345 # be supported by the C++ compiler.)
346 # Figure out how to create a longlong from a string: strtoll and
347 # equiv. It's not enough to call AC_CHECK_FUNCS: hpux has a
348 # strtoll, for instance, but it only takes 2 args instead of 3!
349 # We have to call AH_TEMPLATE since AC_DEFINE_UNQUOTED below is complex.
350 AH_TEMPLATE(HAVE_STRTOQ, [Define to 1 if you have `strtoq'.])
351 AH_TEMPLATE(HAVE_STRTOLL, [Define to 1 if you have `strtoll'.])
352 AH_TEMPLATE(HAVE__STRTOI64, [Define to 1 if you have `_strtoi64'.])
353 AH_TEMPLATE(HAVE_STRTOIMAX, [Define to 1 if you have `strtoimax'.])
354 have_strto_fn=0
355 for fn in srtoq strtoll _strtoi64 strtoimax; do
356 AC_MSG_CHECKING([for $fn])
357 if test "$fn" = strtoimax; then
358 include=stdint.h
359 else
360 include=stdlib.h
361 fi
362 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <$include>],
363 [char* e; return $fn("100", &e, 10)]),
364 [AC_MSG_RESULT(yes)
365 AC_DEFINE_UNQUOTED(HAVE_`echo $fn | tr abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ`, 1,
366 [Define to 1 if you have `$fn'.])
367 have_strto_fn=1
368 break],
369 [AC_MSG_RESULT(no)])
370 done
371
372 if test "$have_strto_fn" = 1; then
373 AC_CHECK_TYPES([long long],
374 [pcre_have_long_long="1"],
375 [pcre_have_long_long="0"])
376 AC_CHECK_TYPES([unsigned long long],
377 [pcre_have_ulong_long="1"],
378 [pcre_have_ulong_long="0"])
379 else
380 pcre_have_long_long="0"
381 pcre_have_ulong_long="0"
382 fi
383 AC_SUBST(pcre_have_long_long)
384 AC_SUBST(pcre_have_ulong_long)
385
386 AC_LANG_POP
387 fi
388 # Using AC_SUBST eliminates the need to include config.h in a public .h file
389 AC_SUBST(pcre_have_type_traits)
390 AC_SUBST(pcre_have_bits_type_traits)
391
392 # Conditional compilation
393 AM_CONDITIONAL(WITH_PCRE_CPP, test "x$enable_cpp" = "xyes")
394 AM_CONDITIONAL(WITH_REBUILD_CHARTABLES, test "x$enable_rebuild_chartables" = "xyes")
395
396 # Checks for typedefs, structures, and compiler characteristics.
397
398 AC_C_CONST
399 AC_TYPE_SIZE_T
400
401 # Checks for library functions.
402
403 AC_CHECK_FUNCS(bcopy memmove strerror)
404
405 # Check for the availability of libz (aka zlib)
406
407 AC_CHECK_HEADERS([zlib.h], [HAVE_ZLIB_H=1])
408 AC_CHECK_LIB([z], [gzopen], [HAVE_LIBZ=1])
409
410 # Check for the availability of libbz2. Originally we just used AC_CHECK_LIB,
411 # as for libz. However, this had the following problem, diagnosed and fixed by
412 # a user:
413 #
414 # - libbz2 uses the Pascal calling convention (WINAPI) for the functions
415 # under Win32.
416 # - The standard autoconf AC_CHECK_LIB fails to include "bzlib.h",
417 # therefore missing the function definition.
418 # - The compiler thus generates a "C" signature for the test function.
419 # - The linker fails to find the "C" function.
420 # - PCRE fails to configure if asked to do so against libbz2.
421 #
422 # Solution:
423 #
424 # - Replace the AC_CHECK_LIB test with a custom test.
425
426 AC_CHECK_HEADERS([bzlib.h], [HAVE_BZLIB_H=1])
427 # Original test
428 # AC_CHECK_LIB([bz2], [BZ2_bzopen], [HAVE_LIBBZ2=1])
429 #
430 # Custom test follows
431
432 AC_MSG_CHECKING([for libbz2])
433 OLD_LIBS="$LIBS"
434 LIBS="$LIBS -lbz2"
435 AC_LINK_IFELSE( AC_LANG_PROGRAM([[
436 #ifdef HAVE_BZLIB_H
437 #include <bzlib.h>
438 #endif]],
439 [[return (int)BZ2_bzopen("conftest", "rb");]]),
440 [AC_MSG_RESULT([yes]);HAVE_LIBBZ2=1; break;],
441 AC_MSG_RESULT([no]))
442 LIBS="$OLD_LIBS"
443
444 # Check for the availabiity of libreadline
445
446 AC_CHECK_HEADERS([readline/readline.h], [HAVE_READLINE_H=1])
447 AC_CHECK_HEADERS([readline/history.h], [HAVE_HISTORY_H=1])
448 AC_CHECK_LIB([readline], [readline], [HAVE_LIB_READLINE=1])
449
450 # This facilitates -ansi builds under Linux
451 dnl AC_DEFINE([_GNU_SOURCE], [], [Enable GNU extensions in glibc])
452
453 PCRE_STATIC_CFLAG=""
454 if test "x$enable_shared" = "xno" ; then
455 AC_DEFINE([PCRE_STATIC], [1], [
456 Define if linking statically (TODO: make nice with Libtool)])
457 PCRE_STATIC_CFLAG="-DPCRE_STATIC"
458 fi
459 AC_SUBST(PCRE_STATIC_CFLAG)
460
461 # Here is where pcre specific defines are handled
462
463 if test "$enable_utf8" = "yes"; then
464 AC_DEFINE([SUPPORT_UTF8], [], [
465 Define to enable support for the UTF-8 Unicode encoding. This will
466 work even in an EBCDIC environment, but it is incompatible with
467 the EBCDIC macro. That is, PCRE can support *either* EBCDIC code
468 *or* ASCII/UTF-8, but not both at once.])
469 fi
470
471 if test "$enable_unicode_properties" = "yes"; then
472 AC_DEFINE([SUPPORT_UCP], [], [
473 Define to enable support for Unicode properties])
474 fi
475
476 if test "$enable_stack_for_recursion" = "no"; then
477 AC_DEFINE([NO_RECURSE], [], [
478 PCRE uses recursive function calls to handle backtracking while
479 matching. This can sometimes be a problem on systems that have
480 stacks of limited size. Define NO_RECURSE to get a version that
481 doesn't use recursion in the match() function; instead it creates
482 its own stack by steam using pcre_recurse_malloc() to obtain memory
483 from the heap. For more detail, see the comments and other stuff
484 just above the match() function. On systems that support it,
485 "configure" can be used to set this in the Makefile
486 (use --disable-stack-for-recursion).])
487 fi
488
489 if test "$enable_pcregrep_libz" = "yes"; then
490 AC_DEFINE([SUPPORT_LIBZ], [], [
491 Define to allow pcregrep to be linked with libz, so that it is
492 able to handle .gz files.])
493 fi
494
495 if test "$enable_pcregrep_libbz2" = "yes"; then
496 AC_DEFINE([SUPPORT_LIBBZ2], [], [
497 Define to allow pcregrep to be linked with libbz2, so that it is
498 able to handle .bz2 files.])
499 fi
500
501 if test "$enable_pcretest_libreadline" = "yes"; then
502 AC_DEFINE([SUPPORT_LIBREADLINE], [], [
503 Define to allow pcretest to be linked with libreadline.])
504 fi
505
506 AC_DEFINE_UNQUOTED([NEWLINE], [$ac_pcre_newline_value], [
507 The value of NEWLINE determines the newline character sequence. On
508 systems that support it, "configure" can be used to override the
509 default, which is 10. The possible values are 10 (LF), 13 (CR),
510 3338 (CRLF), -1 (ANY), or -2 (ANYCRLF).])
511
512 if test "$enable_bsr_anycrlf" = "yes"; then
513 AC_DEFINE([BSR_ANYCRLF], [], [
514 By default, the \R escape sequence matches any Unicode line ending
515 character or sequence of characters. If BSR_ANYCRLF is defined, this is
516 changed so that backslash-R matches only CR, LF, or CRLF. The build-
517 time default can be overridden by the user of PCRE at runtime. On
518 systems that support it, "configure" can be used to override the
519 default.])
520 fi
521
522 AC_DEFINE_UNQUOTED([LINK_SIZE], [$with_link_size], [
523 The value of LINK_SIZE determines the number of bytes used to store
524 links as offsets within the compiled regex. The default is 2, which
525 allows for compiled patterns up to 64K long. This covers the vast
526 majority of cases. However, PCRE can also be compiled to use 3 or 4
527 bytes instead. This allows for longer patterns in extreme cases. On
528 systems that support it, "configure" can be used to override this default.])
529
530 AC_DEFINE_UNQUOTED([POSIX_MALLOC_THRESHOLD], [$with_posix_malloc_threshold], [
531 When calling PCRE via the POSIX interface, additional working storage
532 is required for holding the pointers to capturing substrings because
533 PCRE requires three integers per substring, whereas the POSIX
534 interface provides only two. If the number of expected substrings is
535 small, the wrapper function uses space on the stack, because this is
536 faster than using malloc() for each call. The threshold above which
537 the stack is no longer used is defined by POSIX_MALLOC_THRESHOLD. On
538 systems that support it, "configure" can be used to override this
539 default.])
540
541 AC_DEFINE_UNQUOTED([MATCH_LIMIT], [$with_match_limit], [
542 The value of MATCH_LIMIT determines the default number of times the
543 internal match() function can be called during a single execution of
544 pcre_exec(). There is a runtime interface for setting a different
545 limit. The limit exists in order to catch runaway regular
546 expressions that take for ever to determine that they do not match.
547 The default is set very large so that it does not accidentally catch
548 legitimate cases. On systems that support it, "configure" can be
549 used to override this default default.])
550
551 AC_DEFINE_UNQUOTED([MATCH_LIMIT_RECURSION], [$with_match_limit_recursion], [
552 The above limit applies to all calls of match(), whether or not they
553 increase the recursion depth. In some environments it is desirable
554 to limit the depth of recursive calls of match() more strictly, in
555 order to restrict the maximum amount of stack (or heap, if
556 NO_RECURSE is defined) that is used. The value of
557 MATCH_LIMIT_RECURSION applies only to recursive calls of match(). To
558 have any useful effect, it must be less than the value of
559 MATCH_LIMIT. The default is to use the same value as MATCH_LIMIT.
560 There is a runtime method for setting a different limit. On systems
561 that support it, "configure" can be used to override the default.])
562
563 AC_DEFINE([MAX_NAME_SIZE], [32], [
564 This limit is parameterized just in case anybody ever wants to
565 change it. Care must be taken if it is increased, because it guards
566 against integer overflow caused by enormously large patterns.])
567
568 AC_DEFINE([MAX_NAME_COUNT], [10000], [
569 This limit is parameterized just in case anybody ever wants to
570 change it. Care must be taken if it is increased, because it guards
571 against integer overflow caused by enormously large patterns.])
572
573 AH_VERBATIM([PCRE_EXP_DEFN], [
574 /* If you are compiling for a system other than a Unix-like system or
575 Win32, and it needs some magic to be inserted before the definition
576 of a function that is exported by the library, define this macro to
577 contain the relevant magic. If you do not define this macro, it
578 defaults to "extern" for a C compiler and "extern C" for a C++
579 compiler on non-Win32 systems. This macro apears at the start of
580 every exported function that is part of the external API. It does
581 not appear on functions that are "external" in the C sense, but
582 which are internal to the library. */
583 #undef PCRE_EXP_DEFN])
584
585 if test "$enable_ebcdic" = "yes"; then
586 AC_DEFINE_UNQUOTED([EBCDIC], [], [
587 If you are compiling for a system that uses EBCDIC instead of ASCII
588 character codes, define this macro as 1. On systems that can use
589 "configure", this can be done via --enable-ebcdic. PCRE will then
590 assume that all input strings are in EBCDIC. If you do not define
591 this macro, PCRE will assume input strings are ASCII or UTF-8 Unicode.
592 It is not possible to build a version of PCRE that supports both
593 EBCDIC and UTF-8.])
594 fi
595
596 # Platform specific issues
597 NO_UNDEFINED=
598 EXPORT_ALL_SYMBOLS=
599 case $host_os in
600 cygwin* | mingw* )
601 if test X"$enable_shared" = Xyes; then
602 NO_UNDEFINED="-no-undefined"
603 EXPORT_ALL_SYMBOLS="-Wl,--export-all-symbols"
604 fi
605 ;;
606 esac
607
608 # The extra LDFLAGS for each particular library
609 # (Note: The libpcre*_version bits are m4 variables, assigned above)
610
611 EXTRA_LIBPCRE_LDFLAGS="$EXTRA_LIBPCRE_LDFLAGS \
612 $NO_UNDEFINED -version-info libpcre_version"
613
614 EXTRA_LIBPCREPOSIX_LDFLAGS="$EXTRA_LIBPCREPOSIX_LDFLAGS \
615 $NO_UNDEFINED -version-info libpcreposix_version"
616
617 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS \
618 $NO_UNDEFINED -version-info libpcrecpp_version \
619 $EXPORT_ALL_SYMBOLS"
620
621 AC_SUBST(EXTRA_LIBPCRE_LDFLAGS)
622 AC_SUBST(EXTRA_LIBPCREPOSIX_LDFLAGS)
623 AC_SUBST(EXTRA_LIBPCRECPP_LDFLAGS)
624
625 # When we run 'make distcheck', use these arguments.
626 DISTCHECK_CONFIGURE_FLAGS="--enable-cpp --enable-unicode-properties"
627 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
628
629 # Check that, if --enable-pcregrep-libz or --enable-pcregrep-libbz2 is
630 # specified, the relevant library is available.
631
632 if test "$enable_pcregrep_libz" = "yes"; then
633 if test "$HAVE_ZLIB_H" != "1"; then
634 echo "** Cannot --enable-pcregrep-libz because zlib.h was not found"
635 exit 1
636 fi
637 if test "$HAVE_LIBZ" != "1"; then
638 echo "** Cannot --enable-pcregrep-libz because libz was not found"
639 exit 1
640 fi
641 LIBZ="-lz"
642 fi
643 AC_SUBST(LIBZ)
644
645 if test "$enable_pcregrep_libbz2" = "yes"; then
646 if test "$HAVE_BZLIB_H" != "1"; then
647 echo "** Cannot --enable-pcregrep-libbz2 because bzlib.h was not found"
648 exit 1
649 fi
650 if test "$HAVE_LIBBZ2" != "1"; then
651 echo "** Cannot --enable-pcregrep-libbz2 because libbz2 was not found"
652 exit 1
653 fi
654 LIBBZ2="-lbz2"
655 fi
656 AC_SUBST(LIBBZ2)
657
658 # Similarly for --enable-pcretest-readline
659
660 if test "$enable_pcretest_libreadline" = "yes"; then
661 if test "$HAVE_READLINE_H" != "1"; then
662 echo "** Cannot --enable-pcretest-readline because readline/readline.h was not found."
663 exit 1
664 fi
665 if test "$HAVE_HISTORY_H" != "1"; then
666 echo "** Cannot --enable-pcretest-readline because readline/history.h was not found."
667 exit 1
668 fi
669 LIBREADLINE="-lreadline"
670 fi
671 AC_SUBST(LIBREADLINE)
672
673 # Produce these files, in addition to config.h.
674 AC_CONFIG_FILES(
675 Makefile
676 libpcre.pc
677 libpcreposix.pc
678 libpcrecpp.pc
679 pcre-config
680 pcre.h
681 pcre_stringpiece.h
682 pcrecpparg.h
683 )
684
685 # Make the generated script files executable.
686 AC_CONFIG_COMMANDS([script-chmod], [chmod a+x pcre-config])
687
688 # Make sure that pcre_chartables.c is removed in case the method for
689 # creating it was changed by reconfiguration.
690 AC_CONFIG_COMMANDS([delete-old-chartables], [rm -f pcre_chartables.c])
691
692 AC_OUTPUT
693
694 # Print out a nice little message after configure is run displaying your
695 # chosen options.
696
697 cat <<EOF
698
699 $PACKAGE-$VERSION configuration summary:
700
701 Install prefix .................. : ${prefix}
702 C preprocessor .................. : ${CPP}
703 C compiler ...................... : ${CC}
704 C++ preprocessor ................ : ${CXXCPP}
705 C++ compiler .................... : ${CXX}
706 Linker .......................... : ${LD}
707 C preprocessor flags ............ : ${CPPFLAGS}
708 C compiler flags ................ : ${CFLAGS}
709 C++ compiler flags .............. : ${CXXFLAGS}
710 Linker flags .................... : ${LDFLAGS}
711 Extra libraries ................. : ${LIBS}
712
713 Build C++ library ............... : ${enable_cpp}
714 Enable UTF-8 support ............ : ${enable_utf8}
715 Unicode properties .............. : ${enable_unicode_properties}
716 Newline char/sequence ........... : ${enable_newline}
717 \R matches only ANYCRLF ......... : ${enable_bsr_anycrlf}
718 EBCDIC coding ................... : ${enable_ebcdic}
719 Rebuild char tables ............. : ${enable_rebuild_chartables}
720 Use stack recursion ............. : ${enable_stack_for_recursion}
721 POSIX mem threshold ............. : ${with_posix_malloc_threshold}
722 Internal link size .............. : ${with_link_size}
723 Match limit ..................... : ${with_match_limit}
724 Match limit recursion ........... : ${with_match_limit_recursion}
725 Build shared libs ............... : ${enable_shared}
726 Build static libs ............... : ${enable_static}
727 Link pcregrep with libz ......... : ${enable_pcregrep_libz}
728 Link pcregrep with libbz2 ....... : ${enable_pcregrep_libbz2}
729 Link pcretest with libreadline .. : ${enable_pcretest_libreadline}
730
731 EOF
732
733 dnl end configure.ac

Properties

Name Value
svn:eol-style native
svn:keywords "Author Date Id Revision Url"

webmaster@exim.org
ViewVC Help
Powered by ViewVC 1.1.12