/[pcre]/code/trunk/configure.ac
ViewVC logotype

Contents of /code/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 391 - (show annotations) (download)
Tue Mar 17 21:16:01 2009 UTC (5 years, 6 months ago) by ph10
File size: 25064 byte(s)
Add support for UTF-8 in EBCDIC environments.

1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl NOTE FOR MAINTAINERS: Do not use major or minor version numbers with
4 dnl leading zeros, because they may be treated as octal constants. The
5 dnl PCRE_PRERELEASE feature is for identifying release candidates. It might
6 dnl be defined as -RC2, for example. For real releases, it should be defined
7 dnl empty.
8
9 m4_define(pcre_major, [7])
10 m4_define(pcre_minor, [9])
11 m4_define(pcre_prerelease, [-RC1])
12 m4_define(pcre_date, [2009-02-27])
13
14 # Libtool shared library interface versions (current:revision:age)
15 m4_define(libpcre_version, [0:1:0])
16 m4_define(libpcreposix_version, [0:0:0])
17 m4_define(libpcrecpp_version, [0:0:0])
18
19 AC_PREREQ(2.57)
20 AC_INIT(PCRE, pcre_major.pcre_minor[]pcre_prerelease, , pcre)
21 AC_CONFIG_SRCDIR([pcre.h.in])
22 AM_INIT_AUTOMAKE([dist-bzip2 dist-zip])
23 AC_CONFIG_HEADERS(config.h)
24
25 # The default CFLAGS and CXXFLAGS in Autoconf are "-g -O2" for gcc and just
26 # "-g" for any other compiler. There doesn't seem to be a standard way of
27 # getting rid of the -g (which I don't think is needed for a production
28 # library). This fudge seems to achieve the necessary. First, we remember the
29 # externally set values of CFLAGS and CXXFLAGS. Then call the AC_PROG_CC and
30 # AC_PROG_CXX macros to find the compilers - if CFLAGS and CXXFLAGS are not
31 # set, they will be set to Autoconf's defaults. Afterwards, if the original
32 # values were not set, remove the -g from the Autoconf defaults.
33 # (PH 02-May-07)
34
35 remember_set_CFLAGS="$CFLAGS"
36 remember_set_CXXFLAGS="$CXXFLAGS"
37
38 AC_PROG_CC
39 AC_PROG_CXX
40
41 if test "x$remember_set_CFLAGS" = "x"
42 then
43 if test "$CFLAGS" = "-g -O2"
44 then
45 CFLAGS="-O2"
46 elif test "$CFLAGS" = "-g"
47 then
48 CFLAGS=""
49 fi
50 fi
51
52 if test "x$remember_set_CXXFLAGS" = "x"
53 then
54 if test "$CXXFLAGS" = "-g -O2"
55 then
56 CXXFLAGS="-O2"
57 elif test "$CXXFLAGS" = "-g"
58 then
59 CXXFLAGS=""
60 fi
61 fi
62
63 # AC_PROG_CXX will return "g++" even if no c++ compiler is installed.
64 # Check for that case, and just disable c++ code if g++ doesn't run.
65 AC_LANG_PUSH(C++)
66 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[]),, CXX=""; CXXCP=""; CXXFLAGS="")
67 AC_LANG_POP
68
69 AC_PROG_INSTALL
70 AC_LIBTOOL_WIN32_DLL
71 AC_PROG_LIBTOOL
72 AC_PROG_LN_S
73
74 PCRE_MAJOR="pcre_major"
75 PCRE_MINOR="pcre_minor"
76 PCRE_PRERELEASE="pcre_prerelease"
77 PCRE_DATE="pcre_date"
78
79 AC_SUBST(PCRE_MAJOR)
80 AC_SUBST(PCRE_MINOR)
81 AC_SUBST(PCRE_PRERELEASE)
82 AC_SUBST(PCRE_DATE)
83
84 # Set a more sensible default value for $(htmldir).
85 if test "x$htmldir" = 'x${docdir}'
86 then
87 htmldir='${docdir}/html'
88 fi
89
90 # Handle --disable-cpp
91 AC_ARG_ENABLE(cpp,
92 AS_HELP_STRING([--disable-cpp],
93 [disable C++ support]),
94 , enable_cpp=yes)
95
96 # Handle --enable-rebuild-chartables
97 AC_ARG_ENABLE(rebuild-chartables,
98 AS_HELP_STRING([--enable-rebuild-chartables],
99 [rebuild character tables in current locale]),
100 , enable_rebuild_chartables=no)
101
102 # Handle --enable-utf8 (disabled by default)
103 AC_ARG_ENABLE(utf8,
104 AS_HELP_STRING([--enable-utf8],
105 [enable UTF-8 support (incompatible with --enable-ebcdic)]),
106 , enable_utf8=unset)
107
108 # Handle --enable-unicode-properties
109 AC_ARG_ENABLE(unicode-properties,
110 AS_HELP_STRING([--enable-unicode-properties],
111 [enable Unicode properties support (implies --enable-utf8)]),
112 , enable_unicode_properties=no)
113
114 # Handle --enable-newline=NL
115 dnl AC_ARG_ENABLE(newline,
116 dnl AS_HELP_STRING([--enable-newline=NL],
117 dnl [use NL as newline (lf, cr, crlf, anycrlf, any; default=lf)]),
118 dnl , enable_newline=lf)
119
120 # Separate newline options
121 ac_pcre_newline=lf
122 AC_ARG_ENABLE(newline-is-cr,
123 AS_HELP_STRING([--enable-newline-is-cr],
124 [use CR as newline character]),
125 ac_pcre_newline=cr)
126 AC_ARG_ENABLE(newline-is-lf,
127 AS_HELP_STRING([--enable-newline-is-lf],
128 [use LF as newline character (default)]),
129 ac_pcre_newline=lf)
130 AC_ARG_ENABLE(newline-is-crlf,
131 AS_HELP_STRING([--enable-newline-is-crlf],
132 [use CRLF as newline sequence]),
133 ac_pcre_newline=crlf)
134 AC_ARG_ENABLE(newline-is-anycrlf,
135 AS_HELP_STRING([--enable-newline-is-anycrlf],
136 [use CR, LF, or CRLF as newline sequence]),
137 ac_pcre_newline=anycrlf)
138 AC_ARG_ENABLE(newline-is-any,
139 AS_HELP_STRING([--enable-newline-is-any],
140 [use any valid Unicode newline sequence]),
141 ac_pcre_newline=any)
142 enable_newline="$ac_pcre_newline"
143
144 # Handle --enable-bsr-anycrlf
145 AC_ARG_ENABLE(bsr-anycrlf,
146 AS_HELP_STRING([--enable-bsr-anycrlf],
147 [\R matches only CR, LF, CRLF by default]),
148 , enable_bsr_anycrlf=no)
149
150 # Handle --enable-ebcdic
151 AC_ARG_ENABLE(ebcdic,
152 AS_HELP_STRING([--enable-ebcdic],
153 [assume EBCDIC coding rather than ASCII; incompatible with --enable-utf8; use only in (uncommon) EBCDIC environments; it implies --enable-rebuild-chartables]),
154 , enable_ebcdic=no)
155
156 # Handle --disable-stack-for-recursion
157 AC_ARG_ENABLE(stack-for-recursion,
158 AS_HELP_STRING([--disable-stack-for-recursion],
159 [don't use stack recursion when matching]),
160 , enable_stack_for_recursion=yes)
161
162 # Handle --enable-pcregrep-libz
163 AC_ARG_ENABLE(pcregrep-libz,
164 AS_HELP_STRING([--enable-pcregrep-libz],
165 [link pcregrep with libz to handle .gz files]),
166 , enable_pcregrep_libz=no)
167
168 # Handle --enable-pcregrep-libbz2
169 AC_ARG_ENABLE(pcregrep-libbz2,
170 AS_HELP_STRING([--enable-pcregrep-libbz2],
171 [link pcregrep with libbz2 to handle .bz2 files]),
172 , enable_pcregrep_libbz2=no)
173
174 # Handle --enable-pcretest-libreadline
175 AC_ARG_ENABLE(pcretest-libreadline,
176 AS_HELP_STRING([--enable-pcretest-libreadline],
177 [link pcretest with libreadline]),
178 , enable_pcretest_libreadline=no)
179
180 # Handle --with-posix-malloc-threshold=NBYTES
181 AC_ARG_WITH(posix-malloc-threshold,
182 AS_HELP_STRING([--with-posix-malloc-threshold=NBYTES],
183 [threshold for POSIX malloc usage (default=10)]),
184 , with_posix_malloc_threshold=10)
185
186 # Handle --with-link-size=N
187 AC_ARG_WITH(link-size,
188 AS_HELP_STRING([--with-link-size=N],
189 [internal link size (2, 3, or 4 allowed; default=2)]),
190 , with_link_size=2)
191
192 # Handle --with-match-limit=N
193 AC_ARG_WITH(match-limit,
194 AS_HELP_STRING([--with-match-limit=N],
195 [default limit on internal looping (default=10000000)]),
196 , with_match_limit=10000000)
197
198 # Handle --with-match-limit_recursion=N
199 #
200 # Note: In config.h, the default is to define MATCH_LIMIT_RECURSION
201 # symbolically as MATCH_LIMIT, which in turn is defined to be some numeric
202 # value (e.g. 10000000). MATCH_LIMIT_RECURSION can otherwise be set to some
203 # different numeric value (or even the same numeric value as MATCH_LIMIT,
204 # though no longer defined in terms of the latter).
205 #
206 AC_ARG_WITH(match-limit-recursion,
207 AS_HELP_STRING([--with-match-limit-recursion=N],
208 [default limit on internal recursion (default=MATCH_LIMIT)]),
209 , with_match_limit_recursion=MATCH_LIMIT)
210
211 # Make sure that if enable_unicode_properties was set, that UTF-8 support
212 # is enabled.
213 #
214 if test "x$enable_unicode_properties" = "xyes"
215 then
216 if test "x$enable_utf8" = "xno"
217 then
218 AC_MSG_ERROR([support for Unicode properties requires UTF-8 support])
219 fi
220 enable_utf8=yes
221 fi
222
223 if test "x$enable_utf8" = "xunset"
224 then
225 enable_utf8=no
226 fi
227
228 # Make sure that if enable_ebcdic is set, rebuild_chartables is also enabled.
229 # Also check that UTF-8 support is not requested, because PCRE cannot handle
230 # EBCDIC and UTF-8 in the same build. To do so it would need to use different
231 # character constants depending on the mode.
232 #
233 if test "x$enable_ebcdic" = "xyes"
234 then
235 enable_rebuild_chartables=yes
236 if test "x$enable_utf8" = "xyes"
237 then
238 AC_MSG_ERROR([support for EBCDIC and UTF-8 cannot be enabled at the same time])
239 fi
240 fi
241
242 # Convert the newline identifier into the appropriate integer value.
243 case "$enable_newline" in
244 lf) ac_pcre_newline_value=10 ;;
245 cr) ac_pcre_newline_value=13 ;;
246 crlf) ac_pcre_newline_value=3338 ;;
247 anycrlf) ac_pcre_newline_value=-2 ;;
248 any) ac_pcre_newline_value=-1 ;;
249 *)
250 AC_MSG_ERROR([invalid argument \"$enable_newline\" to --enable-newline option])
251 ;;
252 esac
253
254 # Check argument to --with-link-size
255 case "$with_link_size" in
256 2|3|4) ;;
257 *)
258 AC_MSG_ERROR([invalid argument \"$with_link_size\" to --with-link-size option])
259 ;;
260 esac
261
262 AH_TOP([
263 /* On Unix-like systems config.h.in is converted by "configure" into config.h.
264 Some other environments also support the use of "configure". PCRE is written in
265 Standard C, but there are a few non-standard things it can cope with, allowing
266 it to run on SunOS4 and other "close to standard" systems.
267
268 If you are going to build PCRE "by hand" on a system without "configure" you
269 should copy the distributed config.h.generic to config.h, and then set up the
270 macro definitions the way you need them. You must then add -DHAVE_CONFIG_H to
271 all of your compile commands, so that config.h is included at the start of
272 every source.
273
274 Alternatively, you can avoid editing by using -D on the compiler command line
275 to set the macro values. In this case, you do not have to set -DHAVE_CONFIG_H.
276
277 PCRE uses memmove() if HAVE_MEMMOVE is set to 1; otherwise it uses bcopy() if
278 HAVE_BCOPY is set to 1. If your system has neither bcopy() nor memmove(), set
279 them both to 0; an emulation function will be used. */])
280
281 # Checks for header files.
282 AC_HEADER_STDC
283 AC_CHECK_HEADERS(limits.h sys/types.h sys/stat.h dirent.h windows.h)
284
285 # The files below are C++ header files.
286 pcre_have_type_traits="0"
287 pcre_have_bits_type_traits="0"
288 if test "x$enable_cpp" = "xyes" -a -n "$CXX"
289 then
290 AC_LANG_PUSH(C++)
291
292 # Older versions of pcre defined pcrecpp::no_arg, but in new versions
293 # it's called pcrecpp::RE::no_arg. For backwards ABI compatibility,
294 # we want to make one an alias for the other. Different systems do
295 # this in different ways. Some systems, for instance, can do it via
296 # a linker flag: -alias (for os x 10.5) or -i (for os x <=10.4).
297 OLD_LDFLAGS="$LDFLAGS"
298 for flag in "-alias,__ZN7pcrecpp2RE6no_argE,__ZN7pcrecpp6no_argE" \
299 "-i__ZN7pcrecpp6no_argE:__ZN7pcrecpp2RE6no_argE"; do
300 AC_MSG_CHECKING([for alias support in the linker])
301 LDFLAGS="$OLD_LDFLAGS -Wl,$flag"
302 # We try to run the linker with this new ld flag. If the link fails,
303 # we give up and remove the new flag from LDFLAGS.
304 AC_LINK_IFELSE(AC_LANG_PROGRAM([namespace pcrecpp {
305 class RE { static int no_arg; };
306 int RE::no_arg;
307 }],
308 []),
309 [AC_MSG_RESULT([yes]);
310 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS -Wl,$flag";
311 break;],
312 AC_MSG_RESULT([no]))
313 done
314 LDFLAGS="$OLD_LDFLAGS"
315
316 # We could be more clever here, given we're doing AC_SUBST with this
317 # (eg set a var to be the name of the include file we want). But we're not
318 # so it's easy to change back to 'regular' autoconf vars if we needed to.
319 AC_CHECK_HEADERS(string, [pcre_have_cpp_headers="1"],
320 [pcre_have_cpp_headers="0"])
321 AC_CHECK_HEADERS(bits/type_traits.h, [pcre_have_bits_type_traits="1"],
322 [pcre_have_bits_type_traits="0"])
323 AC_CHECK_HEADERS(type_traits.h, [pcre_have_type_traits="1"],
324 [pcre_have_type_traits="0"])
325
326 AC_LANG_POP
327 fi
328 # Using AC_SUBST eliminates the need to include config.h in a public .h file
329 AC_SUBST(pcre_have_type_traits)
330 AC_SUBST(pcre_have_bits_type_traits)
331
332 # Conditional compilation
333 AM_CONDITIONAL(WITH_PCRE_CPP, test "x$enable_cpp" = "xyes")
334 AM_CONDITIONAL(WITH_REBUILD_CHARTABLES, test "x$enable_rebuild_chartables" = "xyes")
335
336 # Checks for typedefs, structures, and compiler characteristics.
337
338 AC_C_CONST
339 AC_TYPE_SIZE_T
340
341 pcre_have_strotolonglong=0
342 AC_CHECK_FUNCS(strtoq strtoll _strtoi64, [pcre_have_strotolonglong="1"; break])
343 # If we can't convert a string to a long long, pretend we don't even
344 # have a long long.
345 if test $pcre_have_strotolonglong = "0"; then
346 pcre_have_long_long="0"
347 pcre_have_ulong_long="0"
348 else
349 AC_CHECK_TYPES([long long],
350 [pcre_have_long_long="1"],
351 [pcre_have_long_long="0"])
352 AC_CHECK_TYPES([unsigned long long],
353 [pcre_have_ulong_long="1"],
354 [pcre_have_ulong_long="0"])
355 fi
356 AC_SUBST(pcre_have_long_long)
357 AC_SUBST(pcre_have_ulong_long)
358
359 # Checks for library functions.
360
361 AC_CHECK_FUNCS(bcopy memmove strerror)
362
363 # Check for the availability of libz (aka zlib)
364
365 AC_CHECK_HEADERS([zlib.h], [HAVE_ZLIB_H=1])
366 AC_CHECK_LIB([z], [gzopen], [HAVE_LIBZ=1])
367
368 # Check for the availability of libbz2
369
370 AC_CHECK_HEADERS([bzlib.h], [HAVE_BZLIB_H=1])
371 AC_CHECK_LIB([bz2], [BZ2_bzopen], [HAVE_LIBBZ2=1])
372
373 # Check for the availabiity of libreadline
374
375 AC_CHECK_HEADERS([readline/readline.h], [HAVE_READLINE_H=1])
376 AC_CHECK_HEADERS([readline/history.h], [HAVE_HISTORY_H=1])
377 AC_CHECK_LIB([readline], [readline], [HAVE_LIB_READLINE=1])
378
379 # This facilitates -ansi builds under Linux
380 dnl AC_DEFINE([_GNU_SOURCE], [], [Enable GNU extensions in glibc])
381
382 if test "x$enable_shared" = "xno" ; then
383 AC_DEFINE([PCRE_STATIC], [1], [
384 Define if linking statically (TODO: make nice with Libtool)])
385 fi
386
387 # Here is where pcre specific defines are handled
388
389 if test "$enable_utf8" = "yes"; then
390 AC_DEFINE([SUPPORT_UTF8], [], [
391 Define to enable support for the UTF-8 Unicode encoding. This will
392 work even in an EBCDIC environment, but it is incompatible with
393 the EBCDIC macro. That is, PCRE can support *either* EBCDIC code
394 *or* ASCII/UTF-8, but not both at once.])
395 fi
396
397 if test "$enable_unicode_properties" = "yes"; then
398 AC_DEFINE([SUPPORT_UCP], [], [
399 Define to enable support for Unicode properties])
400 fi
401
402 if test "$enable_stack_for_recursion" = "no"; then
403 AC_DEFINE([NO_RECURSE], [], [
404 PCRE uses recursive function calls to handle backtracking while
405 matching. This can sometimes be a problem on systems that have
406 stacks of limited size. Define NO_RECURSE to get a version that
407 doesn't use recursion in the match() function; instead it creates
408 its own stack by steam using pcre_recurse_malloc() to obtain memory
409 from the heap. For more detail, see the comments and other stuff
410 just above the match() function. On systems that support it,
411 "configure" can be used to set this in the Makefile
412 (use --disable-stack-for-recursion).])
413 fi
414
415 if test "$enable_pcregrep_libz" = "yes"; then
416 AC_DEFINE([SUPPORT_LIBZ], [], [
417 Define to allow pcregrep to be linked with libz, so that it is
418 able to handle .gz files.])
419 fi
420
421 if test "$enable_pcregrep_libbz2" = "yes"; then
422 AC_DEFINE([SUPPORT_LIBBZ2], [], [
423 Define to allow pcregrep to be linked with libbz2, so that it is
424 able to handle .bz2 files.])
425 fi
426
427 if test "$enable_pcretest_libreadline" = "yes"; then
428 AC_DEFINE([SUPPORT_LIBREADLINE], [], [
429 Define to allow pcretest to be linked with libreadline.])
430 fi
431
432 AC_DEFINE_UNQUOTED([NEWLINE], [$ac_pcre_newline_value], [
433 The value of NEWLINE determines the newline character sequence. On
434 systems that support it, "configure" can be used to override the
435 default, which is 10. The possible values are 10 (LF), 13 (CR),
436 3338 (CRLF), -1 (ANY), or -2 (ANYCRLF).])
437
438 if test "$enable_bsr_anycrlf" = "yes"; then
439 AC_DEFINE([BSR_ANYCRLF], [], [
440 By default, the \R escape sequence matches any Unicode line ending
441 character or sequence of characters. If BSR_ANYCRLF is defined, this is
442 changed so that backslash-R matches only CR, LF, or CRLF. The build-
443 time default can be overridden by the user of PCRE at runtime. On
444 systems that support it, "configure" can be used to override the
445 default.])
446 fi
447
448 AC_DEFINE_UNQUOTED([LINK_SIZE], [$with_link_size], [
449 The value of LINK_SIZE determines the number of bytes used to store
450 links as offsets within the compiled regex. The default is 2, which
451 allows for compiled patterns up to 64K long. This covers the vast
452 majority of cases. However, PCRE can also be compiled to use 3 or 4
453 bytes instead. This allows for longer patterns in extreme cases. On
454 systems that support it, "configure" can be used to override this default.])
455
456 AC_DEFINE_UNQUOTED([POSIX_MALLOC_THRESHOLD], [$with_posix_malloc_threshold], [
457 When calling PCRE via the POSIX interface, additional working storage
458 is required for holding the pointers to capturing substrings because
459 PCRE requires three integers per substring, whereas the POSIX
460 interface provides only two. If the number of expected substrings is
461 small, the wrapper function uses space on the stack, because this is
462 faster than using malloc() for each call. The threshold above which
463 the stack is no longer used is defined by POSIX_MALLOC_THRESHOLD. On
464 systems that support it, "configure" can be used to override this
465 default.])
466
467 AC_DEFINE_UNQUOTED([MATCH_LIMIT], [$with_match_limit], [
468 The value of MATCH_LIMIT determines the default number of times the
469 internal match() function can be called during a single execution of
470 pcre_exec(). There is a runtime interface for setting a different
471 limit. The limit exists in order to catch runaway regular
472 expressions that take for ever to determine that they do not match.
473 The default is set very large so that it does not accidentally catch
474 legitimate cases. On systems that support it, "configure" can be
475 used to override this default default.])
476
477 AC_DEFINE_UNQUOTED([MATCH_LIMIT_RECURSION], [$with_match_limit_recursion], [
478 The above limit applies to all calls of match(), whether or not they
479 increase the recursion depth. In some environments it is desirable
480 to limit the depth of recursive calls of match() more strictly, in
481 order to restrict the maximum amount of stack (or heap, if
482 NO_RECURSE is defined) that is used. The value of
483 MATCH_LIMIT_RECURSION applies only to recursive calls of match(). To
484 have any useful effect, it must be less than the value of
485 MATCH_LIMIT. The default is to use the same value as MATCH_LIMIT.
486 There is a runtime method for setting a different limit. On systems
487 that support it, "configure" can be used to override the default.])
488
489 AC_DEFINE([MAX_NAME_SIZE], [32], [
490 This limit is parameterized just in case anybody ever wants to
491 change it. Care must be taken if it is increased, because it guards
492 against integer overflow caused by enormously large patterns.])
493
494 AC_DEFINE([MAX_NAME_COUNT], [10000], [
495 This limit is parameterized just in case anybody ever wants to
496 change it. Care must be taken if it is increased, because it guards
497 against integer overflow caused by enormously large patterns.])
498
499 AH_VERBATIM([PCRE_EXP_DEFN], [
500 /* If you are compiling for a system other than a Unix-like system or
501 Win32, and it needs some magic to be inserted before the definition
502 of a function that is exported by the library, define this macro to
503 contain the relevant magic. If you do not define this macro, it
504 defaults to "extern" for a C compiler and "extern C" for a C++
505 compiler on non-Win32 systems. This macro apears at the start of
506 every exported function that is part of the external API. It does
507 not appear on functions that are "external" in the C sense, but
508 which are internal to the library. */
509 #undef PCRE_EXP_DEFN])
510
511 if test "$enable_ebcdic" = "yes"; then
512 AC_DEFINE_UNQUOTED([EBCDIC], [], [
513 If you are compiling for a system that uses EBCDIC instead of ASCII
514 character codes, define this macro as 1. On systems that can use
515 "configure", this can be done via --enable-ebcdic. PCRE will then
516 assume that all input strings are in EBCDIC. If you do not define
517 this macro, PCRE will assume input strings are ASCII or UTF-8 Unicode.
518 It is not possible to build a version of PCRE that supports both
519 EBCDIC and UTF-8.])
520 fi
521
522 # Platform specific issues
523 NO_UNDEFINED=
524 EXPORT_ALL_SYMBOLS=
525 case $host_os in
526 cygwin* | mingw* )
527 if test X"$enable_shared" = Xyes; then
528 NO_UNDEFINED="-no-undefined"
529 EXPORT_ALL_SYMBOLS="-Wl,--export-all-symbols"
530 fi
531 ;;
532 esac
533
534 # The extra LDFLAGS for each particular library
535 # (Note: The libpcre*_version bits are m4 variables, assigned above)
536
537 EXTRA_LIBPCRE_LDFLAGS="$EXTRA_LIBPCRE_LDFLAGS \
538 $NO_UNDEFINED -version-info libpcre_version"
539
540 EXTRA_LIBPCREPOSIX_LDFLAGS="$EXTRA_LIBPCREPOSIX_LDFLAGS \
541 $NO_UNDEFINED -version-info libpcreposix_version"
542
543 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS \
544 $NO_UNDEFINED -version-info libpcrecpp_version \
545 $EXPORT_ALL_SYMBOLS"
546
547 AC_SUBST(EXTRA_LIBPCRE_LDFLAGS)
548 AC_SUBST(EXTRA_LIBPCREPOSIX_LDFLAGS)
549 AC_SUBST(EXTRA_LIBPCRECPP_LDFLAGS)
550
551 # When we run 'make distcheck', use these arguments.
552 DISTCHECK_CONFIGURE_FLAGS="--enable-cpp --enable-unicode-properties"
553 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
554
555 # Check that, if --enable-pcregrep-libz or --enable-pcregrep-libbz2 is
556 # specified, the relevant library is available.
557
558 if test "$enable_pcregrep_libz" = "yes"; then
559 if test "$HAVE_ZLIB_H" != "1"; then
560 echo "** Cannot --enable-pcregrep-libz because zlib.h was not found"
561 exit 1
562 fi
563 if test "$HAVE_LIBZ" != "1"; then
564 echo "** Cannot --enable-pcregrep-libz because libz was not found"
565 exit 1
566 fi
567 LIBZ="-lz"
568 fi
569 AC_SUBST(LIBZ)
570
571 if test "$enable_pcregrep_libbz2" = "yes"; then
572 if test "$HAVE_BZLIB_H" != "1"; then
573 echo "** Cannot --enable-pcregrep-libbz2 because bzlib.h was not found"
574 exit 1
575 fi
576 if test "$HAVE_LIBBZ2" != "1"; then
577 echo "** Cannot --enable-pcregrep-libbz2 because libbz2 was not found"
578 exit 1
579 fi
580 LIBBZ2="-lbz2"
581 fi
582 AC_SUBST(LIBBZ2)
583
584 # Similarly for --enable-pcretest-readline
585
586 if test "$enable_pcretest_libreadline" = "yes"; then
587 if test "$HAVE_READLINE_H" != "1"; then
588 echo "** Cannot --enable-pcretest-readline because readline/readline.h was not found."
589 exit 1
590 fi
591 if test "$HAVE_HISTORY_H" != "1"; then
592 echo "** Cannot --enable-pcretest-readline because readline/history.h was not found."
593 exit 1
594 fi
595 LIBREADLINE="-lreadline"
596 fi
597 AC_SUBST(LIBREADLINE)
598
599 # Produce these files, in addition to config.h.
600 AC_CONFIG_FILES(
601 Makefile
602 libpcre.pc
603 libpcrecpp.pc
604 pcre-config
605 pcre.h
606 pcre_stringpiece.h
607 pcrecpparg.h
608 )
609
610 # Make the generated script files executable.
611 AC_CONFIG_COMMANDS([script-chmod], [chmod a+x pcre-config])
612
613 # Make sure that pcre_chartables.c is removed in case the method for
614 # creating it was changed by reconfiguration.
615 AC_CONFIG_COMMANDS([delete-old-chartables], [rm -f pcre_chartables.c])
616
617 AC_OUTPUT
618
619 # Print out a nice little message after configure is run displaying your
620 # chosen options.
621
622 cat <<EOF
623
624 $PACKAGE-$VERSION configuration summary:
625
626 Install prefix .................. : ${prefix}
627 C preprocessor .................. : ${CPP}
628 C compiler ...................... : ${CC}
629 C++ preprocessor ................ : ${CXXCPP}
630 C++ compiler .................... : ${CXX}
631 Linker .......................... : ${LD}
632 C preprocessor flags ............ : ${CPPFLAGS}
633 C compiler flags ................ : ${CFLAGS}
634 C++ compiler flags .............. : ${CXXFLAGS}
635 Linker flags .................... : ${LDFLAGS}
636 Extra libraries ................. : ${LIBS}
637
638 Build C++ library ............... : ${enable_cpp}
639 Enable UTF-8 support ............ : ${enable_utf8}
640 Unicode properties .............. : ${enable_unicode_properties}
641 Newline char/sequence ........... : ${enable_newline}
642 \R matches only ANYCRLF ......... : ${enable_bsr_anycrlf}
643 EBCDIC coding ................... : ${enable_ebcdic}
644 Rebuild char tables ............. : ${enable_rebuild_chartables}
645 Use stack recursion ............. : ${enable_stack_for_recursion}
646 POSIX mem threshold ............. : ${with_posix_malloc_threshold}
647 Internal link size .............. : ${with_link_size}
648 Match limit ..................... : ${with_match_limit}
649 Match limit recursion ........... : ${with_match_limit_recursion}
650 Build shared libs ............... : ${enable_shared}
651 Build static libs ............... : ${enable_static}
652 Link pcregrep with libz ......... : ${enable_pcregrep_libz}
653 Link pcregrep with libbz2 ....... : ${enable_pcregrep_libbz2}
654 Link pcretest with libreadline .. : ${enable_pcretest_libreadline}
655
656 EOF
657
658 dnl end configure.ac

Properties

Name Value
svn:eol-style native
svn:keywords "Author Date Id Revision Url"

webmaster@exim.org
ViewVC Help
Powered by ViewVC 1.1.12