/[pcre]/code/trunk/configure.ac
ViewVC logotype

Contents of /code/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 286 - (show annotations) (download)
Mon Dec 17 14:46:11 2007 UTC (6 years, 9 months ago) by ph10
File size: 21132 byte(s)
Add .gz and .bz2 optional support to pcregrep.

1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl NOTE FOR MAINTAINERS: Do not use major or minor version numbers with
4 dnl leading zeros, because they may be treated as octal constants. The
5 dnl PCRE_PRERELEASE feature is for identifying release candidates. It might
6 dnl be defined as -RC2, for example. For real releases, it should be defined
7 dnl empty.
8
9 m4_define(pcre_major, [7])
10 m4_define(pcre_minor, [5])
11 m4_define(pcre_prerelease, [-RC1])
12 m4_define(pcre_date, [2007-11-12])
13
14 # Libtool shared library interface versions (current:revision:age)
15 m4_define(libpcre_version, [0:1:0])
16 m4_define(libpcreposix_version, [0:0:0])
17 m4_define(libpcrecpp_version, [0:0:0])
18
19 AC_PREREQ(2.57)
20 AC_INIT(PCRE, pcre_major.pcre_minor[]pcre_prerelease, , pcre)
21 AC_CONFIG_SRCDIR([pcre.h.in])
22 AM_INIT_AUTOMAKE([dist-bzip2 dist-zip])
23 AC_CONFIG_HEADERS(config.h)
24
25 # The default CFLAGS and CXXFLAGS in Autoconf are "-g -O2" for gcc and just
26 # "-g" for any other compiler. There doesn't seem to be a standard way of
27 # getting rid of the -g (which I don't think is needed for a production
28 # library). This fudge seems to achieve the necessary. First, we remember the
29 # externally set values of CFLAGS and CXXFLAGS. Then call the AC_PROG_CC and
30 # AC_PROG_CXX macros to find the compilers - if CFLAGS and CXXFLAGS are not
31 # set, they will be set to Autoconf's defaults. Afterwards, if the original
32 # values were not set, remove the -g from the Autoconf defaults.
33 # (PH 02-May-07)
34
35 remember_set_CFLAGS="$CFLAGS"
36 remember_set_CXXFLAGS="$CXXFLAGS"
37
38 AC_PROG_CC
39 AC_PROG_CXX
40
41 if test "x$remember_set_CFLAGS" = "x"
42 then
43 if test "$CFLAGS" = "-g -O2"
44 then
45 CFLAGS="-O2"
46 elif test "$CFLAGS" = "-g"
47 then
48 CFLAGS=""
49 fi
50 fi
51
52 if test "x$remember_set_CXXFLAGS" = "x"
53 then
54 if test "$CXXFLAGS" = "-g -O2"
55 then
56 CXXFLAGS="-O2"
57 elif test "$CXXFLAGS" = "-g"
58 then
59 CXXFLAGS=""
60 fi
61 fi
62
63
64 AC_PROG_INSTALL
65 AC_LIBTOOL_WIN32_DLL
66 AC_PROG_LIBTOOL
67 AC_PROG_LN_S
68
69 PCRE_MAJOR="pcre_major"
70 PCRE_MINOR="pcre_minor"
71 PCRE_PRERELEASE="pcre_prerelease"
72 PCRE_DATE="pcre_date"
73
74 AC_SUBST(PCRE_MAJOR)
75 AC_SUBST(PCRE_MINOR)
76 AC_SUBST(PCRE_PRERELEASE)
77 AC_SUBST(PCRE_DATE)
78
79 # Set a more sensible default value for $(htmldir).
80 if test "x$htmldir" = 'x${docdir}'
81 then
82 htmldir='${docdir}/html'
83 fi
84
85 # Handle --disable-cpp
86 AC_ARG_ENABLE(cpp,
87 AS_HELP_STRING([--disable-cpp],
88 [disable C++ support]),
89 , enable_cpp=yes)
90
91 # Handle --enable-rebuild-chartables
92 AC_ARG_ENABLE(rebuild-chartables,
93 AS_HELP_STRING([--enable-rebuild-chartables],
94 [rebuild character tables in current locale]),
95 , enable_rebuild_chartables=no)
96
97 # Handle --enable-utf8 (disabled by default)
98 AC_ARG_ENABLE(utf8,
99 AS_HELP_STRING([--enable-utf8],
100 [enable UTF-8 support]),
101 , enable_utf8=unset)
102
103 # Handle --enable-unicode-properties
104 AC_ARG_ENABLE(unicode-properties,
105 AS_HELP_STRING([--enable-unicode-properties],
106 [enable Unicode properties support (implies --enable-utf8)]),
107 , enable_unicode_properties=no)
108
109 # Handle --enable-newline=NL
110 dnl AC_ARG_ENABLE(newline,
111 dnl AS_HELP_STRING([--enable-newline=NL],
112 dnl [use NL as newline (lf, cr, crlf, anycrlf, any; default=lf)]),
113 dnl , enable_newline=lf)
114
115 # Separate newline options
116 ac_pcre_newline=lf
117 AC_ARG_ENABLE(newline-is-cr,
118 AS_HELP_STRING([--enable-newline-is-cr],
119 [use CR as newline character]),
120 ac_pcre_newline=cr)
121 AC_ARG_ENABLE(newline-is-lf,
122 AS_HELP_STRING([--enable-newline-is-lf],
123 [use LF as newline character (default)]),
124 ac_pcre_newline=lf)
125 AC_ARG_ENABLE(newline-is-crlf,
126 AS_HELP_STRING([--enable-newline-is-crlf],
127 [use CRLF as newline sequence]),
128 ac_pcre_newline=crlf)
129 AC_ARG_ENABLE(newline-is-anycrlf,
130 AS_HELP_STRING([--enable-newline-is-anycrlf],
131 [use CR, LF, or CRLF as newline sequence]),
132 ac_pcre_newline=anycrlf)
133 AC_ARG_ENABLE(newline-is-any,
134 AS_HELP_STRING([--enable-newline-is-any],
135 [use any valid Unicode newline sequence]),
136 ac_pcre_newline=any)
137 enable_newline="$ac_pcre_newline"
138
139 # Handle --enable-bsr-anycrlf
140 AC_ARG_ENABLE(bsr-anycrlf,
141 AS_HELP_STRING([--enable-bsr-anycrlf],
142 [\R matches only CR, LF, CRLF by default]),
143 , enable_bsr_anycrlf=no)
144
145 # Handle --enable-ebcdic
146 AC_ARG_ENABLE(ebcdic,
147 AS_HELP_STRING([--enable-ebcdic],
148 [assume EBCDIC coding rather than ASCII; use this only in (uncommon) EBCDIC environments; it implies --enable-rebuild-chartables]),
149 , enable_ebcdic=no)
150
151 # Handle --disable-stack-for-recursion
152 AC_ARG_ENABLE(stack-for-recursion,
153 AS_HELP_STRING([--disable-stack-for-recursion],
154 [don't use stack recursion when matching]),
155 , enable_stack_for_recursion=yes)
156
157 # Handle --enable-pcregrep-libz
158 AC_ARG_ENABLE(pcregrep-libz,
159 AS_HELP_STRING([--enable-pcregrep-libz],
160 [link pcregrep with libz to handle .gz files]),
161 , enable_pcregrep_libz=no)
162
163 # Handle --enable-pcregrep-libbz2
164 AC_ARG_ENABLE(pcregrep-libbz2,
165 AS_HELP_STRING([--enable-pcregrep-libbz2],
166 [link pcregrep with libbz2 to handle .bz2 files]),
167 , enable_pcregrep_libbz2=no)
168
169 # Handle --with-posix-malloc-threshold=NBYTES
170 AC_ARG_WITH(posix-malloc-threshold,
171 AS_HELP_STRING([--with-posix-malloc-threshold=NBYTES],
172 [threshold for POSIX malloc usage (default=10)]),
173 , with_posix_malloc_threshold=10)
174
175 # Handle --with-link-size=N
176 AC_ARG_WITH(link-size,
177 AS_HELP_STRING([--with-link-size=N],
178 [internal link size (2, 3, or 4 allowed; default=2)]),
179 , with_link_size=2)
180
181 # Handle --with-match-limit=N
182 AC_ARG_WITH(match-limit,
183 AS_HELP_STRING([--with-match-limit=N],
184 [default limit on internal looping (default=10000000)]),
185 , with_match_limit=10000000)
186
187 # Handle --with-match-limit_recursion=N
188 #
189 # Note: In config.h, the default is to define MATCH_LIMIT_RECURSION
190 # symbolically as MATCH_LIMIT, which in turn is defined to be some numeric
191 # value (e.g. 10000000). MATCH_LIMIT_RECURSION can otherwise be set to some
192 # different numeric value (or even the same numeric value as MATCH_LIMIT,
193 # though no longer defined in terms of the latter).
194 #
195 AC_ARG_WITH(match-limit-recursion,
196 AS_HELP_STRING([--with-match-limit-recursion=N],
197 [default limit on internal recursion (default=MATCH_LIMIT)]),
198 , with_match_limit_recursion=MATCH_LIMIT)
199
200 # Make sure that if enable_unicode_properties was set, that UTF-8 support
201 # is enabled.
202 #
203 if test "x$enable_unicode_properties" = "xyes"
204 then
205 if test "x$enable_utf8" = "xno"
206 then
207 AC_MSG_ERROR([support for Unicode properties requires UTF-8 support])
208 fi
209 enable_utf8=yes
210 fi
211
212 if test "x$enable_utf8" = "xunset"
213 then
214 enable_utf8=no
215 fi
216
217 # Make sure that if enable_ebcdic is set, rebuild_chartables is also enabled.
218 #
219 if test "x$enable_ebcdic" = "xyes"
220 then
221 enable_rebuild_chartables=yes
222 fi
223
224 # Convert the newline identifier into the appropriate integer value.
225 case "$enable_newline" in
226 lf) ac_pcre_newline_value=10 ;;
227 cr) ac_pcre_newline_value=13 ;;
228 crlf) ac_pcre_newline_value=3338 ;;
229 anycrlf) ac_pcre_newline_value=-2 ;;
230 any) ac_pcre_newline_value=-1 ;;
231 *)
232 AC_MSG_ERROR([invalid argument \"$enable_newline\" to --enable-newline option])
233 ;;
234 esac
235
236 # Check argument to --with-link-size
237 case "$with_link_size" in
238 2|3|4) ;;
239 *)
240 AC_MSG_ERROR([invalid argument \"$with_link_size\" to --with-link-size option])
241 ;;
242 esac
243
244 AH_TOP([
245 /* On Unix-like systems config.h.in is converted by "configure" into config.h.
246 Some other environments also support the use of "configure". PCRE is written in
247 Standard C, but there are a few non-standard things it can cope with, allowing
248 it to run on SunOS4 and other "close to standard" systems.
249
250 If you are going to build PCRE "by hand" on a system without "configure" you
251 should copy the distributed config.h.generic to config.h, and then set up the
252 macro definitions the way you need them. You must then add -DHAVE_CONFIG_H to
253 all of your compile commands, so that config.h is included at the start of
254 every source.
255
256 Alternatively, you can avoid editing by using -D on the compiler command line
257 to set the macro values. In this case, you do not have to set -DHAVE_CONFIG_H.
258
259 PCRE uses memmove() if HAVE_MEMMOVE is set to 1; otherwise it uses bcopy() if
260 HAVE_BCOPY is set to 1. If your system has neither bcopy() nor memmove(), set
261 them both to 0; an emulation function will be used. */])
262
263 # Checks for header files.
264 AC_HEADER_STDC
265 AC_CHECK_HEADERS(limits.h sys/types.h sys/stat.h dirent.h windows.h)
266
267 # The files below are C++ header files.
268 pcre_have_type_traits="0"
269 pcre_have_bits_type_traits="0"
270 if test "x$enable_cpp" = "xyes" -a -n "$CXX"
271 then
272 AC_LANG_PUSH(C++)
273
274 # We could be more clever here, given we're doing AC_SUBST with this
275 # (eg set a var to be the name of the include file we want). But we're not
276 # so it's easy to change back to 'regular' autoconf vars if we needed to.
277 AC_CHECK_HEADERS(string, [pcre_have_cpp_headers="1"],
278 [pcre_have_cpp_headers="0"])
279 AC_CHECK_HEADERS(bits/type_traits.h, [pcre_have_bits_type_traits="1"],
280 [pcre_have_bits_type_traits="0"])
281 AC_CHECK_HEADERS(type_traits.h, [pcre_have_type_traits="1"],
282 [pcre_have_type_traits="0"])
283 AC_LANG_POP
284 fi
285 # Using AC_SUBST eliminates the need to include config.h in a public .h file
286 AC_SUBST(pcre_have_type_traits)
287 AC_SUBST(pcre_have_bits_type_traits)
288
289 # Conditional compilation
290 AM_CONDITIONAL(WITH_PCRE_CPP, test "x$enable_cpp" = "xyes")
291 AM_CONDITIONAL(WITH_REBUILD_CHARTABLES, test "x$enable_rebuild_chartables" = "xyes")
292
293 # Checks for typedefs, structures, and compiler characteristics.
294
295 AC_C_CONST
296 AC_TYPE_SIZE_T
297
298 AC_CHECK_TYPES([long long],
299 [pcre_have_long_long="1"],
300 [pcre_have_long_long="0"])
301 AC_CHECK_TYPES([unsigned long long],
302 [pcre_have_ulong_long="1"],
303 [pcre_have_ulong_long="0"])
304 AC_SUBST(pcre_have_long_long)
305 AC_SUBST(pcre_have_ulong_long)
306
307 # Checks for library functions.
308
309 AC_CHECK_FUNCS(bcopy memmove strerror strtoq strtoll _strtoi64)
310
311 # Check for the availability of libz (aka zlib)
312
313 AC_CHECK_HEADERS([zlib.h], [HAVE_ZLIB_H=1])
314 AC_CHECK_LIB([z], [gzopen], [HAVE_LIBZ=1])
315
316 # Check for the availability of libbz2
317
318 AC_CHECK_HEADERS([bzlib.h], [HAVE_BZLIB_H=1])
319 AC_CHECK_LIB([bz2], [BZ2_bzopen], [HAVE_LIBBZ2=1])
320
321 # This facilitates -ansi builds under Linux
322 dnl AC_DEFINE([_GNU_SOURCE], [], [Enable GNU extensions in glibc])
323
324 if test "x$enable_shared" = "xno" ; then
325 AC_DEFINE([PCRE_STATIC], [1], [
326 Define if linking statically (TODO: make nice with Libtool)])
327 fi
328
329 # Here is where pcre specific defines are handled
330
331 if test "$enable_utf8" = "yes"; then
332 AC_DEFINE([SUPPORT_UTF8], [], [
333 Define to enable support for the UTF-8 Unicode encoding.])
334 fi
335
336 if test "$enable_unicode_properties" = "yes"; then
337 AC_DEFINE([SUPPORT_UCP], [], [
338 Define to enable support for Unicode properties])
339 fi
340
341 if test "$enable_stack_for_recursion" = "no"; then
342 AC_DEFINE([NO_RECURSE], [], [
343 PCRE uses recursive function calls to handle backtracking while
344 matching. This can sometimes be a problem on systems that have
345 stacks of limited size. Define NO_RECURSE to get a version that
346 doesn't use recursion in the match() function; instead it creates
347 its own stack by steam using pcre_recurse_malloc() to obtain memory
348 from the heap. For more detail, see the comments and other stuff
349 just above the match() function. On systems that support it,
350 "configure" can be used to set this in the Makefile
351 (use --disable-stack-for-recursion).])
352 fi
353
354 if test "$enable_pcregrep_libz" = "yes"; then
355 AC_DEFINE([SUPPORT_LIBZ], [], [
356 Define to allow pcregrep to be linked with libz, so that it is
357 able to handle .gz files.])
358 fi
359
360 if test "$enable_pcregrep_libbz2" = "yes"; then
361 AC_DEFINE([SUPPORT_LIBBZ2], [], [
362 Define to allow pcregrep to be linked with libbz2, so that it is
363 able to handle .bz2 files.])
364 fi
365
366 AC_DEFINE_UNQUOTED([NEWLINE], [$ac_pcre_newline_value], [
367 The value of NEWLINE determines the newline character sequence. On
368 systems that support it, "configure" can be used to override the
369 default, which is 10. The possible values are 10 (LF), 13 (CR),
370 3338 (CRLF), -1 (ANY), or -2 (ANYCRLF).])
371
372 if test "$enable_bsr_anycrlf" = "yes"; then
373 AC_DEFINE([BSR_ANYCRLF], [], [
374 By default, the \R escape sequence matches any Unicode line ending
375 character or sequence of characters. If BSR_ANYCRLF is defined, this is
376 changed so that backslash-R matches only CR, LF, or CRLF. The build-
377 time default can be overridden by the user of PCRE at runtime. On
378 systems that support it, "configure" can be used to override the
379 default.])
380 fi
381
382 AC_DEFINE_UNQUOTED([LINK_SIZE], [$with_link_size], [
383 The value of LINK_SIZE determines the number of bytes used to store
384 links as offsets within the compiled regex. The default is 2, which
385 allows for compiled patterns up to 64K long. This covers the vast
386 majority of cases. However, PCRE can also be compiled to use 3 or 4
387 bytes instead. This allows for longer patterns in extreme cases. On
388 systems that support it, "configure" can be used to override this default.])
389
390 AC_DEFINE_UNQUOTED([POSIX_MALLOC_THRESHOLD], [$with_posix_malloc_threshold], [
391 When calling PCRE via the POSIX interface, additional working storage
392 is required for holding the pointers to capturing substrings because
393 PCRE requires three integers per substring, whereas the POSIX
394 interface provides only two. If the number of expected substrings is
395 small, the wrapper function uses space on the stack, because this is
396 faster than using malloc() for each call. The threshold above which
397 the stack is no longer used is defined by POSIX_MALLOC_THRESHOLD. On
398 systems that support it, "configure" can be used to override this
399 default.])
400
401 AC_DEFINE_UNQUOTED([MATCH_LIMIT], [$with_match_limit], [
402 The value of MATCH_LIMIT determines the default number of times the
403 internal match() function can be called during a single execution of
404 pcre_exec(). There is a runtime interface for setting a different
405 limit. The limit exists in order to catch runaway regular
406 expressions that take for ever to determine that they do not match.
407 The default is set very large so that it does not accidentally catch
408 legitimate cases. On systems that support it, "configure" can be
409 used to override this default default.])
410
411 AC_DEFINE_UNQUOTED([MATCH_LIMIT_RECURSION], [$with_match_limit_recursion], [
412 The above limit applies to all calls of match(), whether or not they
413 increase the recursion depth. In some environments it is desirable
414 to limit the depth of recursive calls of match() more strictly, in
415 order to restrict the maximum amount of stack (or heap, if
416 NO_RECURSE is defined) that is used. The value of
417 MATCH_LIMIT_RECURSION applies only to recursive calls of match(). To
418 have any useful effect, it must be less than the value of
419 MATCH_LIMIT. The default is to use the same value as MATCH_LIMIT.
420 There is a runtime method for setting a different limit. On systems
421 that support it, "configure" can be used to override the default.])
422
423 AC_DEFINE([MAX_NAME_SIZE], [32], [
424 This limit is parameterized just in case anybody ever wants to
425 change it. Care must be taken if it is increased, because it guards
426 against integer overflow caused by enormously large patterns.])
427
428 AC_DEFINE([MAX_NAME_COUNT], [10000], [
429 This limit is parameterized just in case anybody ever wants to
430 change it. Care must be taken if it is increased, because it guards
431 against integer overflow caused by enormously large patterns.])
432
433 AH_VERBATIM([PCRE_EXP_DEFN], [
434 /* If you are compiling for a system other than a Unix-like system or
435 Win32, and it needs some magic to be inserted before the definition
436 of a function that is exported by the library, define this macro to
437 contain the relevant magic. If you do not define this macro, it
438 defaults to "extern" for a C compiler and "extern C" for a C++
439 compiler on non-Win32 systems. This macro apears at the start of
440 every exported function that is part of the external API. It does
441 not appear on functions that are "external" in the C sense, but
442 which are internal to the library. */
443 #undef PCRE_EXP_DEFN])
444
445 if test "$enable_ebcdic" = "yes"; then
446 AC_DEFINE_UNQUOTED([EBCDIC], [], [
447 If you are compiling for a system that uses EBCDIC instead of ASCII
448 character codes, define this macro as 1. On systems that can use
449 "configure", this can be done via --enable-ebcdic.])
450 fi
451
452 # Platform specific issues
453 NO_UNDEFINED=
454 EXPORT_ALL_SYMBOLS=
455 case $host_os in
456 cygwin* | mingw* )
457 if test X"$enable_shared" = Xyes; then
458 NO_UNDEFINED="-no-undefined"
459 EXPORT_ALL_SYMBOLS="-Wl,--export-all-symbols"
460 fi
461 ;;
462 esac
463
464 # The extra LDFLAGS for each particular library
465 # (Note: The libpcre*_version bits are m4 variables, assigned above)
466
467 EXTRA_LIBPCRE_LDFLAGS="$NO_UNDEFINED -version-info libpcre_version"
468
469 EXTRA_LIBPCREPOSIX_LDFLAGS="$NO_UNDEFINED -version-info libpcreposix_version"
470
471 EXTRA_LIBPCRECPP_LDFLAGS="$NO_UNDEFINED $EXPORT_ALL_SYMBOLS -version-info libpcrecpp_version"
472
473 AC_SUBST(EXTRA_LIBPCRE_LDFLAGS)
474 AC_SUBST(EXTRA_LIBPCREPOSIX_LDFLAGS)
475 AC_SUBST(EXTRA_LIBPCRECPP_LDFLAGS)
476
477 # When we run 'make distcheck', use these arguments.
478 DISTCHECK_CONFIGURE_FLAGS="--enable-cpp --enable-unicode-properties"
479 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
480
481 # Check that, if --enable-pcregrep-libz or --enable-pcregrep-libbz2 is
482 # specified, the relevant library is available. If so, add it to LIBS.
483
484 if test "$enable_pcregrep_libz" = "yes"; then
485 if test "$HAVE_ZLIB_H" != "1"; then
486 echo "** Cannot --enable-pcregrep-libz because zlib.h was not found"
487 exit 1
488 fi
489 if test "$HAVE_LIBZ" != "1"; then
490 echo "** Cannot --enable-pcregrep-libz because libz was not found"
491 exit 1
492 fi
493 if test "$LIBS" = ""; then LIBS=-lz; else LIBS="$LIBS -lz"; fi
494 fi
495
496 if test "$enable_pcregrep_libbz2" = "yes"; then
497 if test "$HAVE_BZLIB_H" != "1"; then
498 echo "** Cannot --enable-pcregrep-libbz2 because bzlib.h was not found"
499 exit 1
500 fi
501 if test "$HAVE_LIBBZ2" != "1"; then
502 echo "** Cannot --enable-pcregrep-libbz2 because libbz2 was not found"
503 exit 1
504 fi
505 if test "$LIBS" = ""; then LIBS=-lbz2; else LIBS="$LIBS -lbz2"; fi
506 fi
507
508 # Produce these files, in addition to config.h.
509 AC_CONFIG_FILES(
510 Makefile
511 libpcre.pc
512 libpcrecpp.pc
513 pcre-config
514 pcre.h
515 pcre_stringpiece.h
516 pcrecpparg.h
517 )
518
519 # Make the generated script files executable.
520 AC_CONFIG_COMMANDS([script-chmod], [chmod a+x pcre-config])
521
522 # Make sure that pcre_chartables.c is removed in case the method for
523 # creating it was changed by reconfiguration.
524 AC_CONFIG_COMMANDS([delete-old-chartables], [rm -f pcre_chartables.c])
525
526 AC_OUTPUT
527
528 # Print out a nice little message after configure is run displaying your
529 # chosen options.
530
531 cat <<EOF
532
533 $PACKAGE-$VERSION configuration summary:
534
535 Install prefix ............. : ${prefix}
536 C preprocessor ............. : ${CPP}
537 C compiler ................. : ${CC}
538 C++ preprocessor ........... : ${CXXCPP}
539 C++ compiler ............... : ${CXX}
540 Linker ..................... : ${LD}
541 C preprocessor flags ....... : ${CPPFLAGS}
542 C compiler flags ........... : ${CFLAGS}
543 C++ compiler flags ......... : ${CXXFLAGS}
544 Linker flags ............... : ${LDFLAGS}
545 Extra libraries ............ : ${LIBS}
546
547 Build C++ library .......... : ${enable_cpp}
548 Enable UTF-8 support ....... : ${enable_utf8}
549 Unicode properties ......... : ${enable_unicode_properties}
550 Newline char/sequence ...... : ${enable_newline}
551 \R matches only ANYCRLF .... : ${enable_bsr_anycrlf}
552 EBCDIC coding .............. : ${enable_ebcdic}
553 Rebuild char tables ........ : ${enable_rebuild_chartables}
554 Use stack recursion ........ : ${enable_stack_for_recursion}
555 POSIX mem threshold ........ : ${with_posix_malloc_threshold}
556 Internal link size ......... : ${with_link_size}
557 Match limit ................ : ${with_match_limit}
558 Match limit recursion ...... : ${with_match_limit_recursion}
559 Build shared libs .......... : ${enable_shared}
560 Build static libs .......... : ${enable_static}
561 Link pcregrep with libz .... : ${enable_pcregrep_libz}
562 Link pcregrep with libbz2 .. : ${enable_pcregrep_libbz2}
563
564 EOF
565
566 dnl end configure.ac

Properties

Name Value
svn:eol-style native
svn:keywords "Author Date Id Revision Url"

webmaster@exim.org
ViewVC Help
Powered by ViewVC 1.1.12