/[pcre]/code/trunk/CMakeLists.txt
ViewVC logotype

Contents of /code/trunk/CMakeLists.txt

Parent Directory Parent Directory | Revision Log Revision Log


Revision 312 - (show annotations) (download)
Wed Jan 23 18:02:23 2008 UTC (6 years, 7 months ago) by ph10
File MIME type: text/plain
File size: 16461 byte(s)
Remove the automatic build of pcredemo.

1 # CMakeLists.txt
2 #
3 #
4 # This file allows building PCRE with the CMake configuration and build
5 # tool. Download CMake in source or binary form from http://www.cmake.org/
6 #
7 # Original listfile by Christian Ehrlicher <Ch.Ehrlicher@gmx.de>
8 # Refined and expanded by Daniel Richard G. <skunk@iSKUNK.ORG>
9 # 2007-09-14 mod by Sheri so 7.4 supported configuration options can be entered
10 # 2007-09-19 Adjusted by PH to retain previous default settings
11 # 2007-12-26 (a) On UNIX, use names libpcre instead of just pcre
12 # (b) Ensure pcretest and pcregrep link with the local library,
13 # not a previously-installed one.
14 # (c) Add PCRE_SUPPORT_LIBREADLINE, PCRE_SUPPORT_LIBZ, and
15 # PCRE_SUPPORT_LIBBZ2.
16 # 2008-01-20 Brought up to date to include several new features by Christian
17 # Ehrlicher.
18 # 2008-01-22 Sheri aded options for backward compatibility of library names when
19 # building with minGW:
20 # if "ON", NON_STANDARD_LIB_PREFIX causes shared libraries to
21 # be built without "lib" as prefix. (The libraries will be named pcre.dll,
22 # pcreposix.dll and pcrecpp.dll).
23 # if "ON", NON_STANDARD_LIB_SUFFIX causes shared libraries to
24 # be built with suffix of "-0.dll". (The libraries will be named
25 # libpcre-0.dll, libpcreposix-0.dll and libpcrecpp-0.dll - same names
26 # built by default with Configure and Make.
27 # 2008-01-23 PH removed the automatic build of pcredemo.
28
29 PROJECT(PCRE C CXX)
30
31 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.6)
32
33 SET(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake) # for FindReadline.cmake
34
35 # external packages
36 FIND_PACKAGE( BZip2 )
37 FIND_PACKAGE( ZLIB )
38 FIND_PACKAGE( Readline )
39
40 # Configuration checks
41
42 INCLUDE(CheckIncludeFile)
43 INCLUDE(CheckIncludeFileCXX)
44 INCLUDE(CheckFunctionExists)
45 INCLUDE(CheckTypeSize)
46
47 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
48 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
49 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
50 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
51 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
52
53 CHECK_INCLUDE_FILE_CXX(type_traits.h HAVE_TYPE_TRAITS_H)
54 CHECK_INCLUDE_FILE_CXX(bits/type_traits.h HAVE_BITS_TYPE_TRAITS_H)
55
56 CHECK_FUNCTION_EXISTS(bcopy HAVE_BCOPY)
57 CHECK_FUNCTION_EXISTS(memmove HAVE_MEMMOVE)
58 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
59 CHECK_FUNCTION_EXISTS(strtoll HAVE_STRTOLL)
60 CHECK_FUNCTION_EXISTS(strtoq HAVE_STRTOQ)
61 CHECK_FUNCTION_EXISTS(_strtoi64 HAVE__STRTOI64)
62
63 CHECK_TYPE_SIZE("long long" LONG_LONG)
64 CHECK_TYPE_SIZE("unsigned long long" UNSIGNED_LONG_LONG)
65
66 # User-configurable options
67 #
68 # (Note: CMakeSetup displays these in alphabetical order, regardless of
69 # the order we use here)
70
71 SET(BUILD_SHARED_LIBS OFF CACHE BOOL
72 "Build shared libraries instead of static ones.")
73
74 OPTION(PCRE_BUILD_PCRECPP "Build the PCRE C++ library (pcrecpp)." ON)
75
76 SET(PCRE_EBCDIC OFF CACHE BOOL
77 "Use EBCDIC coding instead of ASCII. (This is rarely used outside of mainframe systems)")
78
79 SET(PCRE_LINK_SIZE "2" CACHE STRING
80 "Internal link size (2, 3 or 4 allowed). See LINK_SIZE in config.h.in for details.")
81
82 SET(PCRE_MATCH_LIMIT "10000000" CACHE STRING
83 "Default limit on internal looping. See MATCH_LIMIT in config.h.in for details.")
84
85 SET(PCRE_MATCH_LIMIT_RECURSION "MATCH_LIMIT" CACHE STRING
86 "Default limit on internal recursion. See MATCH_LIMIT_RECURSION in config.h.in for details.")
87
88 SET(PCRE_NEWLINE "LF" CACHE STRING
89 "What to recognize as a newline (one of CR, LF, CRLF, ANY, ANYCRLF).")
90
91 SET(PCRE_NO_RECURSE OFF CACHE BOOL
92 "If ON, then don't use stack recursion when matching. See NO_RECURSE in config.h.in for details.")
93
94 SET(PCRE_POSIX_MALLOC_THRESHOLD "10" CACHE STRING
95 "Threshold for malloc() usage. See POSIX_MALLOC_THRESHOLD in config.h.in for details.")
96
97 SET(PCRE_SUPPORT_UNICODE_PROPERTIES OFF CACHE BOOL
98 "Enable support for Unicode properties. (If set, UTF-8 support will be enabled as well)")
99
100 SET(PCRE_SUPPORT_UTF8 OFF CACHE BOOL
101 "Enable support for the Unicode UTF-8 encoding.")
102
103 SET(PCRE_SUPPORT_BSR_ANYCRLF OFF CACHE BOOL
104 "ON=Backslash-R matches only LF CR and CRLF, OFF=Backslash-R matches all Unicode Linebreaks")
105
106 SET(NON_STANDARD_LIB_PREFIX OFF CACHE BOOL
107 "ON=Shared libraries built in mingw will be named pcre.dll, etc., instead of libpcre.dll, etc.")
108
109 SET(NON_STANDARD_LIB_SUFFIX OFF CACHE BOOL
110 "ON=Shared libraries built in mingw will be named libpcre-0.dll, etc., instead of libpcre.dll, etc.")
111
112 # bzip2 lib
113 IF(BZIP2_FOUND)
114 OPTION (PCRE_SUPPORT_LIBBZ2 "Enable support for linking pcregrep with libbz2." ON)
115 ENDIF(BZIP2_FOUND)
116 IF(PCRE_SUPPORT_LIBBZ2)
117 INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
118 ENDIF(PCRE_SUPPORT_LIBBZ2)
119
120 # zlib
121 IF(ZLIB_FOUND)
122 OPTION (PCRE_SUPPORT_LIBZ "Enable support for linking pcregrep with libz." ON)
123 ENDIF(ZLIB_FOUND)
124 IF(PCRE_SUPPORT_LIBZ)
125 INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
126 ENDIF(PCRE_SUPPORT_LIBZ)
127
128 # readline lib
129 IF(READLINE_FOUND)
130 OPTION (PCRE_SUPPORT_LIBREADLINE "Enable support for linking pcretest with libreadline." ON)
131 ENDIF(READLINE_FOUND)
132 IF(PCRE_SUPPORT_LIBREADLINE)
133 INCLUDE_DIRECTORIES(${READLINE_INCLUDE_DIR})
134 ENDIF(PCRE_SUPPORT_LIBREADLINE)
135
136 # Prepare build configuration
137
138 SET(pcre_have_type_traits 0)
139 SET(pcre_have_bits_type_traits 0)
140
141 IF(HAVE_TYPE_TRAITS_H)
142 SET(pcre_have_type_traits 1)
143 ENDIF(HAVE_TYPE_TRAITS_H)
144
145 IF(HAVE_BITS_TYPE_TRAITS_H)
146 SET(pcre_have_bits_type_traits 1)
147 ENDIF(HAVE_BITS_TYPE_TRAITS_H)
148
149 SET(pcre_have_long_long 0)
150 SET(pcre_have_ulong_long 0)
151
152 IF(HAVE_LONG_LONG)
153 SET(pcre_have_long_long 1)
154 ENDIF(HAVE_LONG_LONG)
155
156 IF(HAVE_UNSIGNED_LONG_LONG)
157 SET(pcre_have_ulong_long 1)
158 ENDIF(HAVE_UNSIGNED_LONG_LONG)
159
160 IF(NOT BUILD_SHARED_LIBS)
161 SET(PCRE_STATIC 1)
162 ENDIF(NOT BUILD_SHARED_LIBS)
163
164 IF(PCRE_SUPPORT_BSR_ANYCRLF)
165 SET(BSR_ANYCRLF 1)
166 ENDIF(PCRE_SUPPORT_BSR_ANYCRLF)
167
168 IF(PCRE_SUPPORT_UTF8 OR PCRE_SUPPORT_UNICODE_PROPERTIES)
169 SET(SUPPORT_UTF8 1)
170 ENDIF(PCRE_SUPPORT_UTF8 OR PCRE_SUPPORT_UNICODE_PROPERTIES)
171
172 IF(PCRE_SUPPORT_UNICODE_PROPERTIES)
173 SET(SUPPORT_UCP 1)
174 ENDIF(PCRE_SUPPORT_UNICODE_PROPERTIES)
175
176 IF(PCRE_SUPPORT_LIBREADLINE)
177 SET(SUPPORT_LIBREADLINE 1)
178 SET(PCRETEST_LIBS ${READLINE_LIBRARY})
179 ENDIF(PCRE_SUPPORT_LIBREADLINE)
180
181 IF(PCRE_SUPPORT_LIBZ)
182 SET(SUPPORT_LIBZ 1)
183 SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${ZLIB_LIBRARIES})
184 ENDIF(PCRE_SUPPORT_LIBZ)
185
186 IF(PCRE_SUPPORT_LIBBZ2)
187 SET(SUPPORT_LIBBZ2 1)
188 SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${BZIP2_LIBRARIES})
189 ENDIF(PCRE_SUPPORT_LIBBZ2)
190
191 SET(NEWLINE "")
192
193 IF(PCRE_NEWLINE STREQUAL "LF")
194 SET(NEWLINE "10")
195 ENDIF(PCRE_NEWLINE STREQUAL "LF")
196 IF(PCRE_NEWLINE STREQUAL "CR")
197 SET(NEWLINE "13")
198 ENDIF(PCRE_NEWLINE STREQUAL "CR")
199 IF(PCRE_NEWLINE STREQUAL "CRLF")
200 SET(NEWLINE "3338")
201 ENDIF(PCRE_NEWLINE STREQUAL "CRLF")
202 IF(PCRE_NEWLINE STREQUAL "ANY")
203 SET(NEWLINE "-1")
204 ENDIF(PCRE_NEWLINE STREQUAL "ANY")
205 IF(PCRE_NEWLINE STREQUAL "ANYCRLF")
206 SET(NEWLINE "-2")
207 ENDIF(PCRE_NEWLINE STREQUAL "ANYCRLF")
208
209 IF(NEWLINE STREQUAL "")
210 MESSAGE(FATAL_ERROR "The PCRE_NEWLINE variable must be set to one of the following values: \"LF\", \"CR\", \"CRLF\", \"ANY\", \"ANYCRLF\".")
211 ENDIF(NEWLINE STREQUAL "")
212
213 IF(PCRE_EBCDIC)
214 SET(EBCDIC 1)
215 ENDIF(PCRE_EBCDIC)
216
217 IF(PCRE_NO_RECURSE)
218 SET(NO_RECURSE 1)
219 ENDIF(PCRE_NO_RECURSE)
220
221 # Output files
222
223 CONFIGURE_FILE(config-cmake.h.in
224 ${CMAKE_BINARY_DIR}/config.h
225 @ONLY)
226
227 CONFIGURE_FILE(pcre.h.generic
228 ${CMAKE_BINARY_DIR}/pcre.h
229 COPYONLY)
230
231 # What about pcre-config and libpcre.pc?
232
233 IF(PCRE_BUILD_PCRECPP)
234 CONFIGURE_FILE(pcre_stringpiece.h.in
235 ${CMAKE_BINARY_DIR}/pcre_stringpiece.h
236 @ONLY)
237
238 CONFIGURE_FILE(pcrecpparg.h.in
239 ${CMAKE_BINARY_DIR}/pcrecpparg.h
240 @ONLY)
241 ENDIF(PCRE_BUILD_PCRECPP)
242
243 # Character table generation
244
245 OPTION(PCRE_REBUILD_CHARTABLES "Rebuild char tables" OFF)
246 IF(PCRE_REBUILD_CHARTABLES)
247 ADD_EXECUTABLE(dftables dftables.c)
248
249 GET_TARGET_PROPERTY(DFTABLES_EXE dftables LOCATION)
250
251 ADD_CUSTOM_COMMAND(
252 COMMENT "Generating character tables (pcre_chartables.c) for current locale"
253 DEPENDS dftables
254 COMMAND ${DFTABLES_EXE}
255 ARGS ${CMAKE_BINARY_DIR}/pcre_chartables.c
256 OUTPUT ${CMAKE_BINARY_DIR}/pcre_chartables.c
257 )
258 ELSE(PCRE_REBUILD_CHARTABLES)
259 CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/pcre_chartables.c.dist
260 ${CMAKE_BINARY_DIR}/pcre_chartables.c
261 COPYONLY)
262 ENDIF(PCRE_REBUILD_CHARTABLES)
263
264 # Source code
265
266 SET(PCRE_HEADERS ${CMAKE_BINARY_DIR}/pcre.h)
267
268 SET(PCRE_SOURCES
269 ${CMAKE_BINARY_DIR}/pcre_chartables.c
270 pcre_compile.c
271 pcre_config.c
272 pcre_dfa_exec.c
273 pcre_exec.c
274 pcre_fullinfo.c
275 pcre_get.c
276 pcre_globals.c
277 pcre_info.c
278 pcre_newline.c
279 pcre_maketables.c
280 pcre_ord2utf8.c
281 pcre_refcount.c
282 pcre_study.c
283 pcre_tables.c
284 pcre_try_flipped.c
285 pcre_ucp_searchfuncs.c
286 pcre_valid_utf8.c
287 pcre_version.c
288 pcre_xclass.c
289 )
290
291 SET(PCREPOSIX_HEADERS pcreposix.h)
292
293 SET(PCREPOSIX_SOURCES pcreposix.c)
294
295 SET(PCRECPP_HEADERS
296 pcrecpp.h
297 pcre_scanner.h
298 ${CMAKE_BINARY_DIR}/pcrecpparg.h
299 ${CMAKE_BINARY_DIR}/pcre_stringpiece.h
300 )
301
302 SET(PCRECPP_SOURCES
303 pcrecpp.cc
304 pcre_scanner.cc
305 pcre_stringpiece.cc
306 )
307
308 # Build setup
309
310 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
311
312 IF(MSVC)
313 ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
314 ENDIF(MSVC)
315
316 SET(CMAKE_INCLUDE_CURRENT_DIR 1)
317 # needed to make sure to not link debug libs
318 # against release libs and vice versa
319 IF(WIN32)
320 SET(CMAKE_DEBUG_POSTFIX "d")
321 ENDIF(WIN32)
322
323 # Libraries
324
325 ADD_LIBRARY(pcre ${PCRE_HEADERS} ${PCRE_SOURCES} ${CMAKE_BINARY_DIR}/config.h)
326 ADD_LIBRARY(pcreposix ${PCREPOSIX_HEADERS} ${PCREPOSIX_SOURCES})
327 TARGET_LINK_LIBRARIES(pcreposix pcre)
328
329 IF(MINGW AND NON_STANDARD_LIB_PREFIX AND NOT PCRE_STATIC)
330 SET_TARGET_PROPERTIES(pcre pcreposix
331 PROPERTIES PREFIX ""
332 )
333 ENDIF(MINGW AND NON_STANDARD_LIB_PREFIX AND NOT PCRE_STATIC)
334
335 IF(MINGW AND NON_STANDARD_LIB_SUFFIX AND NOT PCRE_STATIC)
336 SET_TARGET_PROPERTIES(pcre pcreposix
337 PROPERTIES SUFFIX "-0.dll"
338 )
339 ENDIF(MINGW AND NON_STANDARD_LIB_SUFFIX AND NOT PCRE_STATIC)
340
341 IF(PCRE_BUILD_PCRECPP)
342 ADD_LIBRARY(pcrecpp ${PCRECPP_HEADERS} ${PCRECPP_SOURCES})
343 TARGET_LINK_LIBRARIES(pcrecpp pcre)
344 IF(MINGW AND NON_STANDARD_LIB_PREFIX AND NOT PCRE_STATIC)
345 SET_TARGET_PROPERTIES(pcrecpp
346 PROPERTIES PREFIX ""
347 )
348 ENDIF(MINGW AND NON_STANDARD_LIB_PREFIX AND NOT PCRE_STATIC)
349 IF(MINGW AND NON_STANDARD_LIB_SUFFIX AND NOT PCRE_STATIC)
350 SET_TARGET_PROPERTIES(pcrecpp
351 PROPERTIES SUFFIX "-0.dll"
352 )
353 ENDIF(MINGW AND NON_STANDARD_LIB_SUFFIX AND NOT PCRE_STATIC)
354
355 ENDIF(PCRE_BUILD_PCRECPP)
356
357 # Executables
358
359 ADD_EXECUTABLE(pcretest pcretest.c)
360 TARGET_LINK_LIBRARIES(pcretest pcreposix ${PCRETEST_LIBS})
361
362 ADD_EXECUTABLE(pcregrep pcregrep.c)
363 TARGET_LINK_LIBRARIES(pcregrep pcreposix ${PCREGREP_LIBS})
364
365 # Removed by PH (2008-01-23) because pcredemo shouldn't really be built
366 # automatically, and it gave trouble in some environments anyway.
367 # ADD_EXECUTABLE(pcredemo pcredemo.c)
368 # TARGET_LINK_LIBRARIES(pcredemo pcreposix)
369 # IF(NOT BUILD_SHARED_LIBS)
370 # # make sure to not use declspec(dllimport) in static mode on windows
371 # SET_TARGET_PROPERTIES(pcredemo PROPERTIES COMPILE_FLAGS "-DPCRE_STATIC")
372 # ENDIF(NOT BUILD_SHARED_LIBS)
373
374 IF(PCRE_BUILD_PCRECPP)
375 ADD_EXECUTABLE(pcrecpp_unittest pcrecpp_unittest.cc)
376 TARGET_LINK_LIBRARIES(pcrecpp_unittest pcrecpp)
377 IF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
378 SET_TARGET_PROPERTIES(pcrecpp
379 PROPERTIES PREFIX ""
380 )
381 ENDIF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
382
383
384 ADD_EXECUTABLE(pcre_scanner_unittest pcre_scanner_unittest.cc)
385 TARGET_LINK_LIBRARIES(pcre_scanner_unittest pcrecpp)
386
387 ADD_EXECUTABLE(pcre_stringpiece_unittest pcre_stringpiece_unittest.cc)
388 TARGET_LINK_LIBRARIES(pcre_stringpiece_unittest pcrecpp)
389 ENDIF(PCRE_BUILD_PCRECPP)
390
391 # Testing
392
393 ENABLE_TESTING()
394
395 GET_TARGET_PROPERTY(PCREGREP_EXE pcregrep DEBUG_LOCATION)
396 GET_TARGET_PROPERTY(PCRETEST_EXE pcretest DEBUG_LOCATION)
397
398 # Write out a CTest configuration file that sets some needed environment
399 # variables for the test scripts.
400 #
401 FILE(WRITE ${CMAKE_BINARY_DIR}/CTestCustom.ctest
402 "# This is a generated file.
403 SET(ENV{srcdir} ${CMAKE_SOURCE_DIR})
404 SET(ENV{pcregrep} ${PCREGREP_EXE})
405 SET(ENV{pcretest} ${PCRETEST_EXE})
406 ")
407
408 IF(UNIX)
409 ADD_TEST(pcre_test ${CMAKE_SOURCE_DIR}/RunTest)
410 ADD_TEST(pcre_grep_test ${CMAKE_SOURCE_DIR}/RunGrepTest)
411 ENDIF(UNIX)
412 IF(WIN32)
413 ADD_TEST(pcre_test cmd /C ${CMAKE_SOURCE_DIR}/RunTest.bat)
414 ENDIF(WIN32)
415
416 GET_TARGET_PROPERTY(PCRECPP_UNITTEST_EXE
417 pcrecpp_unittest
418 DEBUG_LOCATION)
419
420 GET_TARGET_PROPERTY(PCRE_SCANNER_UNITTEST_EXE
421 pcre_scanner_unittest
422 DEBUG_LOCATION)
423
424 GET_TARGET_PROPERTY(PCRE_STRINGPIECE_UNITTEST_EXE
425 pcre_stringpiece_unittest
426 DEBUG_LOCATION)
427
428 ADD_TEST(pcrecpp_test ${PCRECPP_UNITTEST_EXE})
429 ADD_TEST(pcre_scanner_test ${PCRE_SCANNER_UNITTEST_EXE})
430 ADD_TEST(pcre_stringpiece_test ${PCRE_STRINGPIECE_UNITTEST_EXE})
431
432 # Installation
433
434 SET(CMAKE_INSTALL_ALWAYS 1)
435
436 INSTALL(TARGETS pcre pcreposix pcregrep pcretest
437 RUNTIME DESTINATION bin
438 LIBRARY DESTINATION lib
439 ARCHIVE DESTINATION lib)
440
441 INSTALL(FILES ${PCRE_HEADERS} ${PCREPOSIX_HEADERS} DESTINATION include)
442
443 FILE(GLOB html ${CMAKE_SOURCE_DIR}/doc/html/*.html)
444 FILE(GLOB man1 ${CMAKE_SOURCE_DIR}/doc/*.1)
445 FILE(GLOB man3 ${CMAKE_SOURCE_DIR}/doc/*.3)
446
447 IF(PCRE_BUILD_PCRECPP)
448 INSTALL(TARGETS pcrecpp
449 RUNTIME DESTINATION bin
450 LIBRARY DESTINATION lib
451 ARCHIVE DESTINATION lib)
452 INSTALL(FILES ${PCRECPP_HEADERS} DESTINATION include)
453 ELSE(PCRE_BUILD_PCRECPP)
454 # Remove pcrecpp.3
455 FOREACH(man ${man3})
456 GET_FILENAME_COMPONENT(man_tmp ${man} NAME)
457 IF(NOT man_tmp STREQUAL "pcrecpp.3")
458 SET(man3_new ${man3} ${man})
459 ENDIF(NOT man_tmp STREQUAL "pcrecpp.3")
460 ENDFOREACH(man ${man3})
461 SET(man3 ${man3_new})
462 ENDIF(PCRE_BUILD_PCRECPP)
463
464
465 INSTALL(FILES ${man1} DESTINATION man/man1)
466 INSTALL(FILES ${man3} DESTINATION man/man3)
467 INSTALL(FILES ${html} DESTINATION share/doc/pcre/html)
468
469 # help, only for nice output
470 IF(BUILD_SHARED_LIBS)
471 SET(BUILD_STATIC_LIBS OFF)
472 ELSE(BUILD_SHARED_LIBS)
473 SET(BUILD_STATIC_LIBS ON)
474 ENDIF(BUILD_SHARED_LIBS)
475
476 MESSAGE(STATUS "")
477 MESSAGE(STATUS "")
478 MESSAGE(STATUS "PCRE configuration summary:")
479 MESSAGE(STATUS "")
480 MESSAGE(STATUS " Install prefix .................. : " ${CMAKE_INSTALL_PREFIX})
481 MESSAGE(STATUS " C compiler ...................... : " ${CMAKE_C_COMPILER})
482 MESSAGE(STATUS " C++ compiler .................... : " ${CMAKE_CXX_COMPILER})
483 MESSAGE(STATUS " C compiler flags ................ : " ${CMAKE_C_FLAGS}) #FIXME
484 MESSAGE(STATUS " C++ compiler flags .............. : " ${CMAKE_CXX_FLAGS}) #FIXME
485 MESSAGE(STATUS "")
486 MESSAGE(STATUS " Build C++ library ............... : " ${PCRE_BUILD_PCRECPP})
487 MESSAGE(STATUS " Enable UTF-8 support ............ : " ${PCRE_SUPPORT_UNICODE_PROPERTIES})
488 MESSAGE(STATUS " Unicode properties .............. : " ${PCRE_SUPPORT_UNICODE_PROPERTIES})
489 MESSAGE(STATUS " Newline char/sequence ........... : " ${PCRE_NEWLINE})
490 MESSAGE(STATUS " \\R matches only ANYCRLF ......... : " ${PCRE_SUPPORT_BSR_ANYCRLF})
491 MESSAGE(STATUS " EBCDIC coding ................... : " ${PCRE_EBCDIC})
492 MESSAGE(STATUS " Rebuild char tables ............. : " ${PCRE_REBUILD_CHARTABLES})
493 MESSAGE(STATUS " No stack recursion .............. : " ${PCRE_NO_RECURSE})
494 MESSAGE(STATUS " POSIX mem threshold ............. : " ${PCRE_POSIX_MALLOC_THRESHOLD})
495 MESSAGE(STATUS " Internal link size .............. : " ${PCRE_LINK_SIZE})
496 MESSAGE(STATUS " Match limit ..................... : " ${PCRE_MATCH_LIMIT})
497 MESSAGE(STATUS " Match limit recursion ........... : " ${PCRE_MATCH_LIMIT_RECURSION})
498 MESSAGE(STATUS " Build shared libs ............... : " ${BUILD_SHARED_LIBS})
499 MESSAGE(STATUS " Build static libs ............... : " ${BUILD_STATIC_LIBS})
500 IF(ZLIB_FOUND)
501 MESSAGE(STATUS " Link pcregrep with libz ......... : " ${PCRE_SUPPORT_LIBZ})
502 ELSE(ZLIB_FOUND)
503 MESSAGE(STATUS " Link pcregrep with libz ......... : zlib libraries not found!" )
504 ENDIF(ZLIB_FOUND)
505 IF(BZIP2_FOUND)
506 MESSAGE(STATUS " Link pcregrep with libbz2 ....... : " ${PCRE_SUPPORT_LIBBZ2})
507 ELSE(BZIP2_FOUND)
508 MESSAGE(STATUS " Link pcregrep with libbz2 ....... : bzip2 libraries not found!" )
509 ENDIF(BZIP2_FOUND)
510 MESSAGE(STATUS " Link pcretest with libreadline .. : " ${PCRE_SUPPORT_LIBREADLINE})
511 MESSAGE(STATUS "")
512
513 # end CMakeLists.txt

webmaster@exim.org
ViewVC Help
Powered by ViewVC 1.1.12