/[pcre]/code/branches/pcre16/configure.ac
ViewVC logotype

Contents of /code/branches/pcre16/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 592 - (show annotations) (download)
Sat Apr 30 17:37:37 2011 UTC (2 years, 11 months ago) by ph10
Original Path: code/trunk/configure.ac
File size: 27870 byte(s)
Update tables to Unicode 6.0.0.

1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl NOTE FOR MAINTAINERS: Do not use minor version numbers 08 or 09 because
4 dnl the leading zeros may cause them to be treated as invalid octal constants
5 dnl if a PCRE user writes code that uses PCRE_MINOR as a number. There is now
6 dnl a check further down that throws an error if 08 or 09 are used.
7
8 dnl The PCRE_PRERELEASE feature is for identifying release candidates. It might
9 dnl be defined as -RC2, for example. For real releases, it should be empty.
10
11 m4_define(pcre_major, [8])
12 m4_define(pcre_minor, [13])
13 m4_define(pcre_prerelease, [-RC1])
14 m4_define(pcre_date, [2011-04-30])
15
16 # Libtool shared library interface versions (current:revision:age)
17 m4_define(libpcre_version, [0:1:0])
18 m4_define(libpcreposix_version, [0:0:0])
19 m4_define(libpcrecpp_version, [0:0:0])
20
21 AC_PREREQ(2.57)
22 AC_INIT(PCRE, pcre_major.pcre_minor[]pcre_prerelease, , pcre)
23 AC_CONFIG_SRCDIR([pcre.h.in])
24 AM_INIT_AUTOMAKE([dist-bzip2 dist-zip])
25 AC_CONFIG_HEADERS(config.h)
26
27 # This was added at the suggestion of libtoolize (03-Jan-10)
28 AC_CONFIG_MACRO_DIR([m4])
29
30 # The default CFLAGS and CXXFLAGS in Autoconf are "-g -O2" for gcc and just
31 # "-g" for any other compiler. There doesn't seem to be a standard way of
32 # getting rid of the -g (which I don't think is needed for a production
33 # library). This fudge seems to achieve the necessary. First, we remember the
34 # externally set values of CFLAGS and CXXFLAGS. Then call the AC_PROG_CC and
35 # AC_PROG_CXX macros to find the compilers - if CFLAGS and CXXFLAGS are not
36 # set, they will be set to Autoconf's defaults. Afterwards, if the original
37 # values were not set, remove the -g from the Autoconf defaults.
38 # (PH 02-May-07)
39
40 remember_set_CFLAGS="$CFLAGS"
41 remember_set_CXXFLAGS="$CXXFLAGS"
42
43 AC_PROG_CC
44 AC_PROG_CXX
45
46 if test "x$remember_set_CFLAGS" = "x"
47 then
48 if test "$CFLAGS" = "-g -O2"
49 then
50 CFLAGS="-O2"
51 elif test "$CFLAGS" = "-g"
52 then
53 CFLAGS=""
54 fi
55 fi
56
57 if test "x$remember_set_CXXFLAGS" = "x"
58 then
59 if test "$CXXFLAGS" = "-g -O2"
60 then
61 CXXFLAGS="-O2"
62 elif test "$CXXFLAGS" = "-g"
63 then
64 CXXFLAGS=""
65 fi
66 fi
67
68 # AC_PROG_CXX will return "g++" even if no c++ compiler is installed.
69 # Check for that case, and just disable c++ code if g++ doesn't run.
70 AC_LANG_PUSH(C++)
71 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[]),, CXX=""; CXXCP=""; CXXFLAGS="")
72 AC_LANG_POP
73
74 # Check for a 64-bit integer type
75 AC_TYPE_INT64_T
76
77 AC_PROG_INSTALL
78 AC_LIBTOOL_WIN32_DLL
79 AC_PROG_LIBTOOL
80 AC_PROG_LN_S
81
82 PCRE_MAJOR="pcre_major"
83 PCRE_MINOR="pcre_minor"
84 PCRE_PRERELEASE="pcre_prerelease"
85 PCRE_DATE="pcre_date"
86
87 if test "$PCRE_MINOR" = "08" -o "$PCRE_MINOR" = "09"
88 then
89 echo "***"
90 echo "*** Minor version number $PCRE_MINOR must not be used. ***"
91 echo "*** Use only 01 to 07 or 10 onwards, to avoid octal issues. ***"
92 echo "***"
93 exit 1
94 fi
95
96 AC_SUBST(PCRE_MAJOR)
97 AC_SUBST(PCRE_MINOR)
98 AC_SUBST(PCRE_PRERELEASE)
99 AC_SUBST(PCRE_DATE)
100
101 # Set a more sensible default value for $(htmldir).
102 if test "x$htmldir" = 'x${docdir}'
103 then
104 htmldir='${docdir}/html'
105 fi
106
107 # Handle --disable-cpp. The substitution of enable_cpp is needed for use in
108 # pcre-config.
109 AC_ARG_ENABLE(cpp,
110 AS_HELP_STRING([--disable-cpp],
111 [disable C++ support]),
112 , enable_cpp=yes)
113 AC_SUBST(enable_cpp)
114
115 # Handle --enable-rebuild-chartables
116 AC_ARG_ENABLE(rebuild-chartables,
117 AS_HELP_STRING([--enable-rebuild-chartables],
118 [rebuild character tables in current locale]),
119 , enable_rebuild_chartables=no)
120
121 # Handle --enable-utf8 (disabled by default)
122 AC_ARG_ENABLE(utf8,
123 AS_HELP_STRING([--enable-utf8],
124 [enable UTF-8 support (incompatible with --enable-ebcdic)]),
125 , enable_utf8=unset)
126
127 # Handle --enable-unicode-properties
128 AC_ARG_ENABLE(unicode-properties,
129 AS_HELP_STRING([--enable-unicode-properties],
130 [enable Unicode properties support (implies --enable-utf8)]),
131 , enable_unicode_properties=no)
132
133 # Handle --enable-newline=NL
134 dnl AC_ARG_ENABLE(newline,
135 dnl AS_HELP_STRING([--enable-newline=NL],
136 dnl [use NL as newline (lf, cr, crlf, anycrlf, any; default=lf)]),
137 dnl , enable_newline=lf)
138
139 # Separate newline options
140 ac_pcre_newline=lf
141 AC_ARG_ENABLE(newline-is-cr,
142 AS_HELP_STRING([--enable-newline-is-cr],
143 [use CR as newline character]),
144 ac_pcre_newline=cr)
145 AC_ARG_ENABLE(newline-is-lf,
146 AS_HELP_STRING([--enable-newline-is-lf],
147 [use LF as newline character (default)]),
148 ac_pcre_newline=lf)
149 AC_ARG_ENABLE(newline-is-crlf,
150 AS_HELP_STRING([--enable-newline-is-crlf],
151 [use CRLF as newline sequence]),
152 ac_pcre_newline=crlf)
153 AC_ARG_ENABLE(newline-is-anycrlf,
154 AS_HELP_STRING([--enable-newline-is-anycrlf],
155 [use CR, LF, or CRLF as newline sequence]),
156 ac_pcre_newline=anycrlf)
157 AC_ARG_ENABLE(newline-is-any,
158 AS_HELP_STRING([--enable-newline-is-any],
159 [use any valid Unicode newline sequence]),
160 ac_pcre_newline=any)
161 enable_newline="$ac_pcre_newline"
162
163 # Handle --enable-bsr-anycrlf
164 AC_ARG_ENABLE(bsr-anycrlf,
165 AS_HELP_STRING([--enable-bsr-anycrlf],
166 [\R matches only CR, LF, CRLF by default]),
167 , enable_bsr_anycrlf=no)
168
169 # Handle --enable-ebcdic
170 AC_ARG_ENABLE(ebcdic,
171 AS_HELP_STRING([--enable-ebcdic],
172 [assume EBCDIC coding rather than ASCII; incompatible with --enable-utf8; use only in (uncommon) EBCDIC environments; it implies --enable-rebuild-chartables]),
173 , enable_ebcdic=no)
174
175 # Handle --disable-stack-for-recursion
176 AC_ARG_ENABLE(stack-for-recursion,
177 AS_HELP_STRING([--disable-stack-for-recursion],
178 [don't use stack recursion when matching]),
179 , enable_stack_for_recursion=yes)
180
181 # Handle --enable-pcregrep-libz
182 AC_ARG_ENABLE(pcregrep-libz,
183 AS_HELP_STRING([--enable-pcregrep-libz],
184 [link pcregrep with libz to handle .gz files]),
185 , enable_pcregrep_libz=no)
186
187 # Handle --enable-pcregrep-libbz2
188 AC_ARG_ENABLE(pcregrep-libbz2,
189 AS_HELP_STRING([--enable-pcregrep-libbz2],
190 [link pcregrep with libbz2 to handle .bz2 files]),
191 , enable_pcregrep_libbz2=no)
192
193 # Handle --enable-pcretest-libreadline
194 AC_ARG_ENABLE(pcretest-libreadline,
195 AS_HELP_STRING([--enable-pcretest-libreadline],
196 [link pcretest with libreadline]),
197 , enable_pcretest_libreadline=no)
198
199 # Handle --with-posix-malloc-threshold=NBYTES
200 AC_ARG_WITH(posix-malloc-threshold,
201 AS_HELP_STRING([--with-posix-malloc-threshold=NBYTES],
202 [threshold for POSIX malloc usage (default=10)]),
203 , with_posix_malloc_threshold=10)
204
205 # Handle --with-link-size=N
206 AC_ARG_WITH(link-size,
207 AS_HELP_STRING([--with-link-size=N],
208 [internal link size (2, 3, or 4 allowed; default=2)]),
209 , with_link_size=2)
210
211 # Handle --with-match-limit=N
212 AC_ARG_WITH(match-limit,
213 AS_HELP_STRING([--with-match-limit=N],
214 [default limit on internal looping (default=10000000)]),
215 , with_match_limit=10000000)
216
217 # Handle --with-match-limit_recursion=N
218 #
219 # Note: In config.h, the default is to define MATCH_LIMIT_RECURSION
220 # symbolically as MATCH_LIMIT, which in turn is defined to be some numeric
221 # value (e.g. 10000000). MATCH_LIMIT_RECURSION can otherwise be set to some
222 # different numeric value (or even the same numeric value as MATCH_LIMIT,
223 # though no longer defined in terms of the latter).
224 #
225 AC_ARG_WITH(match-limit-recursion,
226 AS_HELP_STRING([--with-match-limit-recursion=N],
227 [default limit on internal recursion (default=MATCH_LIMIT)]),
228 , with_match_limit_recursion=MATCH_LIMIT)
229
230 # Make sure that if enable_unicode_properties was set, that UTF-8 support
231 # is enabled.
232 #
233 if test "x$enable_unicode_properties" = "xyes"
234 then
235 if test "x$enable_utf8" = "xno"
236 then
237 AC_MSG_ERROR([support for Unicode properties requires UTF-8 support])
238 fi
239 enable_utf8=yes
240 fi
241
242 if test "x$enable_utf8" = "xunset"
243 then
244 enable_utf8=no
245 fi
246
247 # Make sure that if enable_ebcdic is set, rebuild_chartables is also enabled.
248 # Also check that UTF-8 support is not requested, because PCRE cannot handle
249 # EBCDIC and UTF-8 in the same build. To do so it would need to use different
250 # character constants depending on the mode.
251 #
252 if test "x$enable_ebcdic" = "xyes"
253 then
254 enable_rebuild_chartables=yes
255 if test "x$enable_utf8" = "xyes"
256 then
257 AC_MSG_ERROR([support for EBCDIC and UTF-8 cannot be enabled at the same time])
258 fi
259 fi
260
261 # Convert the newline identifier into the appropriate integer value.
262 case "$enable_newline" in
263 lf) ac_pcre_newline_value=10 ;;
264 cr) ac_pcre_newline_value=13 ;;
265 crlf) ac_pcre_newline_value=3338 ;;
266 anycrlf) ac_pcre_newline_value=-2 ;;
267 any) ac_pcre_newline_value=-1 ;;
268 *)
269 AC_MSG_ERROR([invalid argument \"$enable_newline\" to --enable-newline option])
270 ;;
271 esac
272
273 # Check argument to --with-link-size
274 case "$with_link_size" in
275 2|3|4) ;;
276 *)
277 AC_MSG_ERROR([invalid argument \"$with_link_size\" to --with-link-size option])
278 ;;
279 esac
280
281 AH_TOP([
282 /* On Unix-like systems config.h.in is converted by "configure" into config.h.
283 Some other environments also support the use of "configure". PCRE is written in
284 Standard C, but there are a few non-standard things it can cope with, allowing
285 it to run on SunOS4 and other "close to standard" systems.
286
287 If you are going to build PCRE "by hand" on a system without "configure" you
288 should copy the distributed config.h.generic to config.h, and then set up the
289 macro definitions the way you need them. You must then add -DHAVE_CONFIG_H to
290 all of your compile commands, so that config.h is included at the start of
291 every source.
292
293 Alternatively, you can avoid editing by using -D on the compiler command line
294 to set the macro values. In this case, you do not have to set -DHAVE_CONFIG_H.
295
296 PCRE uses memmove() if HAVE_MEMMOVE is set to 1; otherwise it uses bcopy() if
297 HAVE_BCOPY is set to 1. If your system has neither bcopy() nor memmove(), set
298 them both to 0; an emulation function will be used. */])
299
300 # Checks for header files.
301 AC_HEADER_STDC
302 AC_CHECK_HEADERS(limits.h sys/types.h sys/stat.h dirent.h windows.h)
303
304 # The files below are C++ header files.
305 pcre_have_type_traits="0"
306 pcre_have_bits_type_traits="0"
307 if test "x$enable_cpp" = "xyes" -a -n "$CXX"
308 then
309 AC_LANG_PUSH(C++)
310
311 # Older versions of pcre defined pcrecpp::no_arg, but in new versions
312 # it's called pcrecpp::RE::no_arg. For backwards ABI compatibility,
313 # we want to make one an alias for the other. Different systems do
314 # this in different ways. Some systems, for instance, can do it via
315 # a linker flag: -alias (for os x 10.5) or -i (for os x <=10.4).
316 OLD_LDFLAGS="$LDFLAGS"
317 for flag in "-alias,__ZN7pcrecpp2RE6no_argE,__ZN7pcrecpp6no_argE" \
318 "-i__ZN7pcrecpp6no_argE:__ZN7pcrecpp2RE6no_argE"; do
319 AC_MSG_CHECKING([for alias support in the linker])
320 LDFLAGS="$OLD_LDFLAGS -Wl,$flag"
321 # We try to run the linker with this new ld flag. If the link fails,
322 # we give up and remove the new flag from LDFLAGS.
323 AC_LINK_IFELSE(AC_LANG_PROGRAM([namespace pcrecpp {
324 class RE { static int no_arg; };
325 int RE::no_arg;
326 }],
327 []),
328 [AC_MSG_RESULT([yes]);
329 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS -Wl,$flag";
330 break;],
331 AC_MSG_RESULT([no]))
332 done
333 LDFLAGS="$OLD_LDFLAGS"
334
335 # We could be more clever here, given we're doing AC_SUBST with this
336 # (eg set a var to be the name of the include file we want). But we're not
337 # so it's easy to change back to 'regular' autoconf vars if we needed to.
338 AC_CHECK_HEADERS(string, [pcre_have_cpp_headers="1"],
339 [pcre_have_cpp_headers="0"])
340 AC_CHECK_HEADERS(bits/type_traits.h, [pcre_have_bits_type_traits="1"],
341 [pcre_have_bits_type_traits="0"])
342 AC_CHECK_HEADERS(type_traits.h, [pcre_have_type_traits="1"],
343 [pcre_have_type_traits="0"])
344
345 # (This isn't c++-specific, but is only used in pcrecpp.cc, so try this
346 # in a c++ context. This matters becuase strtoimax is C99 and may not
347 # be supported by the C++ compiler.)
348 # Figure out how to create a longlong from a string: strtoll and
349 # equiv. It's not enough to call AC_CHECK_FUNCS: hpux has a
350 # strtoll, for instance, but it only takes 2 args instead of 3!
351 # We have to call AH_TEMPLATE since AC_DEFINE_UNQUOTED below is complex.
352 AH_TEMPLATE(HAVE_STRTOQ, [Define to 1 if you have `strtoq'.])
353 AH_TEMPLATE(HAVE_STRTOLL, [Define to 1 if you have `strtoll'.])
354 AH_TEMPLATE(HAVE__STRTOI64, [Define to 1 if you have `_strtoi64'.])
355 AH_TEMPLATE(HAVE_STRTOIMAX, [Define to 1 if you have `strtoimax'.])
356 have_strto_fn=0
357 for fn in strtoq strtoll _strtoi64 strtoimax; do
358 AC_MSG_CHECKING([for $fn])
359 if test "$fn" = strtoimax; then
360 include=stdint.h
361 else
362 include=stdlib.h
363 fi
364 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <$include>],
365 [char* e; return $fn("100", &e, 10)]),
366 [AC_MSG_RESULT(yes)
367 AC_DEFINE_UNQUOTED(HAVE_`echo $fn | tr abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ`, 1,
368 [Define to 1 if you have `$fn'.])
369 have_strto_fn=1
370 break],
371 [AC_MSG_RESULT(no)])
372 done
373
374 if test "$have_strto_fn" = 1; then
375 AC_CHECK_TYPES([long long],
376 [pcre_have_long_long="1"],
377 [pcre_have_long_long="0"])
378 AC_CHECK_TYPES([unsigned long long],
379 [pcre_have_ulong_long="1"],
380 [pcre_have_ulong_long="0"])
381 else
382 pcre_have_long_long="0"
383 pcre_have_ulong_long="0"
384 fi
385 AC_SUBST(pcre_have_long_long)
386 AC_SUBST(pcre_have_ulong_long)
387
388 AC_LANG_POP
389 fi
390 # Using AC_SUBST eliminates the need to include config.h in a public .h file
391 AC_SUBST(pcre_have_type_traits)
392 AC_SUBST(pcre_have_bits_type_traits)
393
394 # Conditional compilation
395 AM_CONDITIONAL(WITH_PCRE_CPP, test "x$enable_cpp" = "xyes")
396 AM_CONDITIONAL(WITH_REBUILD_CHARTABLES, test "x$enable_rebuild_chartables" = "xyes")
397
398 # Checks for typedefs, structures, and compiler characteristics.
399
400 AC_C_CONST
401 AC_TYPE_SIZE_T
402
403 # Checks for library functions.
404
405 AC_CHECK_FUNCS(bcopy memmove strerror)
406
407 # Check for the availability of libz (aka zlib)
408
409 AC_CHECK_HEADERS([zlib.h], [HAVE_ZLIB_H=1])
410 AC_CHECK_LIB([z], [gzopen], [HAVE_LIBZ=1])
411
412 # Check for the availability of libbz2. Originally we just used AC_CHECK_LIB,
413 # as for libz. However, this had the following problem, diagnosed and fixed by
414 # a user:
415 #
416 # - libbz2 uses the Pascal calling convention (WINAPI) for the functions
417 # under Win32.
418 # - The standard autoconf AC_CHECK_LIB fails to include "bzlib.h",
419 # therefore missing the function definition.
420 # - The compiler thus generates a "C" signature for the test function.
421 # - The linker fails to find the "C" function.
422 # - PCRE fails to configure if asked to do so against libbz2.
423 #
424 # Solution:
425 #
426 # - Replace the AC_CHECK_LIB test with a custom test.
427
428 AC_CHECK_HEADERS([bzlib.h], [HAVE_BZLIB_H=1])
429 # Original test
430 # AC_CHECK_LIB([bz2], [BZ2_bzopen], [HAVE_LIBBZ2=1])
431 #
432 # Custom test follows
433
434 AC_MSG_CHECKING([for libbz2])
435 OLD_LIBS="$LIBS"
436 LIBS="$LIBS -lbz2"
437 AC_LINK_IFELSE( AC_LANG_PROGRAM([[
438 #ifdef HAVE_BZLIB_H
439 #include <bzlib.h>
440 #endif]],
441 [[return (int)BZ2_bzopen("conftest", "rb");]]),
442 [AC_MSG_RESULT([yes]);HAVE_LIBBZ2=1; break;],
443 AC_MSG_RESULT([no]))
444 LIBS="$OLD_LIBS"
445
446 # Check for the availabiity of libreadline
447
448 AC_CHECK_HEADERS([readline/readline.h], [HAVE_READLINE_H=1])
449 AC_CHECK_HEADERS([readline/history.h], [HAVE_HISTORY_H=1])
450 AC_CHECK_LIB([readline], [readline], [HAVE_LIB_READLINE=1])
451
452 # This facilitates -ansi builds under Linux
453 dnl AC_DEFINE([_GNU_SOURCE], [], [Enable GNU extensions in glibc])
454
455 PCRE_STATIC_CFLAG=""
456 if test "x$enable_shared" = "xno" ; then
457 AC_DEFINE([PCRE_STATIC], [1], [
458 Define if linking statically (TODO: make nice with Libtool)])
459 PCRE_STATIC_CFLAG="-DPCRE_STATIC"
460 fi
461 AC_SUBST(PCRE_STATIC_CFLAG)
462
463 # Here is where pcre specific defines are handled
464
465 if test "$enable_utf8" = "yes"; then
466 AC_DEFINE([SUPPORT_UTF8], [], [
467 Define to enable support for the UTF-8 Unicode encoding. This will
468 work even in an EBCDIC environment, but it is incompatible with
469 the EBCDIC macro. That is, PCRE can support *either* EBCDIC code
470 *or* ASCII/UTF-8, but not both at once.])
471 fi
472
473 if test "$enable_unicode_properties" = "yes"; then
474 AC_DEFINE([SUPPORT_UCP], [], [
475 Define to enable support for Unicode properties])
476 fi
477
478 if test "$enable_stack_for_recursion" = "no"; then
479 AC_DEFINE([NO_RECURSE], [], [
480 PCRE uses recursive function calls to handle backtracking while
481 matching. This can sometimes be a problem on systems that have
482 stacks of limited size. Define NO_RECURSE to get a version that
483 doesn't use recursion in the match() function; instead it creates
484 its own stack by steam using pcre_recurse_malloc() to obtain memory
485 from the heap. For more detail, see the comments and other stuff
486 just above the match() function. On systems that support it,
487 "configure" can be used to set this in the Makefile
488 (use --disable-stack-for-recursion).])
489 fi
490
491 if test "$enable_pcregrep_libz" = "yes"; then
492 AC_DEFINE([SUPPORT_LIBZ], [], [
493 Define to allow pcregrep to be linked with libz, so that it is
494 able to handle .gz files.])
495 fi
496
497 if test "$enable_pcregrep_libbz2" = "yes"; then
498 AC_DEFINE([SUPPORT_LIBBZ2], [], [
499 Define to allow pcregrep to be linked with libbz2, so that it is
500 able to handle .bz2 files.])
501 fi
502
503 if test "$enable_pcretest_libreadline" = "yes"; then
504 AC_DEFINE([SUPPORT_LIBREADLINE], [], [
505 Define to allow pcretest to be linked with libreadline.])
506 fi
507
508 AC_DEFINE_UNQUOTED([NEWLINE], [$ac_pcre_newline_value], [
509 The value of NEWLINE determines the newline character sequence. On
510 systems that support it, "configure" can be used to override the
511 default, which is 10. The possible values are 10 (LF), 13 (CR),
512 3338 (CRLF), -1 (ANY), or -2 (ANYCRLF).])
513
514 if test "$enable_bsr_anycrlf" = "yes"; then
515 AC_DEFINE([BSR_ANYCRLF], [], [
516 By default, the \R escape sequence matches any Unicode line ending
517 character or sequence of characters. If BSR_ANYCRLF is defined, this is
518 changed so that backslash-R matches only CR, LF, or CRLF. The build-
519 time default can be overridden by the user of PCRE at runtime. On
520 systems that support it, "configure" can be used to override the
521 default.])
522 fi
523
524 AC_DEFINE_UNQUOTED([LINK_SIZE], [$with_link_size], [
525 The value of LINK_SIZE determines the number of bytes used to store
526 links as offsets within the compiled regex. The default is 2, which
527 allows for compiled patterns up to 64K long. This covers the vast
528 majority of cases. However, PCRE can also be compiled to use 3 or 4
529 bytes instead. This allows for longer patterns in extreme cases. On
530 systems that support it, "configure" can be used to override this default.])
531
532 AC_DEFINE_UNQUOTED([POSIX_MALLOC_THRESHOLD], [$with_posix_malloc_threshold], [
533 When calling PCRE via the POSIX interface, additional working storage
534 is required for holding the pointers to capturing substrings because
535 PCRE requires three integers per substring, whereas the POSIX
536 interface provides only two. If the number of expected substrings is
537 small, the wrapper function uses space on the stack, because this is
538 faster than using malloc() for each call. The threshold above which
539 the stack is no longer used is defined by POSIX_MALLOC_THRESHOLD. On
540 systems that support it, "configure" can be used to override this
541 default.])
542
543 AC_DEFINE_UNQUOTED([MATCH_LIMIT], [$with_match_limit], [
544 The value of MATCH_LIMIT determines the default number of times the
545 internal match() function can be called during a single execution of
546 pcre_exec(). There is a runtime interface for setting a different
547 limit. The limit exists in order to catch runaway regular
548 expressions that take for ever to determine that they do not match.
549 The default is set very large so that it does not accidentally catch
550 legitimate cases. On systems that support it, "configure" can be
551 used to override this default default.])
552
553 AC_DEFINE_UNQUOTED([MATCH_LIMIT_RECURSION], [$with_match_limit_recursion], [
554 The above limit applies to all calls of match(), whether or not they
555 increase the recursion depth. In some environments it is desirable
556 to limit the depth of recursive calls of match() more strictly, in
557 order to restrict the maximum amount of stack (or heap, if
558 NO_RECURSE is defined) that is used. The value of
559 MATCH_LIMIT_RECURSION applies only to recursive calls of match(). To
560 have any useful effect, it must be less than the value of
561 MATCH_LIMIT. The default is to use the same value as MATCH_LIMIT.
562 There is a runtime method for setting a different limit. On systems
563 that support it, "configure" can be used to override the default.])
564
565 AC_DEFINE([MAX_NAME_SIZE], [32], [
566 This limit is parameterized just in case anybody ever wants to
567 change it. Care must be taken if it is increased, because it guards
568 against integer overflow caused by enormously large patterns.])
569
570 AC_DEFINE([MAX_NAME_COUNT], [10000], [
571 This limit is parameterized just in case anybody ever wants to
572 change it. Care must be taken if it is increased, because it guards
573 against integer overflow caused by enormously large patterns.])
574
575 AH_VERBATIM([PCRE_EXP_DEFN], [
576 /* If you are compiling for a system other than a Unix-like system or
577 Win32, and it needs some magic to be inserted before the definition
578 of a function that is exported by the library, define this macro to
579 contain the relevant magic. If you do not define this macro, it
580 defaults to "extern" for a C compiler and "extern C" for a C++
581 compiler on non-Win32 systems. This macro apears at the start of
582 every exported function that is part of the external API. It does
583 not appear on functions that are "external" in the C sense, but
584 which are internal to the library. */
585 #undef PCRE_EXP_DEFN])
586
587 if test "$enable_ebcdic" = "yes"; then
588 AC_DEFINE_UNQUOTED([EBCDIC], [], [
589 If you are compiling for a system that uses EBCDIC instead of ASCII
590 character codes, define this macro as 1. On systems that can use
591 "configure", this can be done via --enable-ebcdic. PCRE will then
592 assume that all input strings are in EBCDIC. If you do not define
593 this macro, PCRE will assume input strings are ASCII or UTF-8 Unicode.
594 It is not possible to build a version of PCRE that supports both
595 EBCDIC and UTF-8.])
596 fi
597
598 # Platform specific issues
599 NO_UNDEFINED=
600 EXPORT_ALL_SYMBOLS=
601 case $host_os in
602 cygwin* | mingw* )
603 if test X"$enable_shared" = Xyes; then
604 NO_UNDEFINED="-no-undefined"
605 EXPORT_ALL_SYMBOLS="-Wl,--export-all-symbols"
606 fi
607 ;;
608 esac
609
610 # The extra LDFLAGS for each particular library
611 # (Note: The libpcre*_version bits are m4 variables, assigned above)
612
613 EXTRA_LIBPCRE_LDFLAGS="$EXTRA_LIBPCRE_LDFLAGS \
614 $NO_UNDEFINED -version-info libpcre_version"
615
616 EXTRA_LIBPCREPOSIX_LDFLAGS="$EXTRA_LIBPCREPOSIX_LDFLAGS \
617 $NO_UNDEFINED -version-info libpcreposix_version"
618
619 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS \
620 $NO_UNDEFINED -version-info libpcrecpp_version \
621 $EXPORT_ALL_SYMBOLS"
622
623 AC_SUBST(EXTRA_LIBPCRE_LDFLAGS)
624 AC_SUBST(EXTRA_LIBPCREPOSIX_LDFLAGS)
625 AC_SUBST(EXTRA_LIBPCRECPP_LDFLAGS)
626
627 # When we run 'make distcheck', use these arguments.
628 DISTCHECK_CONFIGURE_FLAGS="--enable-cpp --enable-unicode-properties"
629 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
630
631 # Check that, if --enable-pcregrep-libz or --enable-pcregrep-libbz2 is
632 # specified, the relevant library is available.
633
634 if test "$enable_pcregrep_libz" = "yes"; then
635 if test "$HAVE_ZLIB_H" != "1"; then
636 echo "** Cannot --enable-pcregrep-libz because zlib.h was not found"
637 exit 1
638 fi
639 if test "$HAVE_LIBZ" != "1"; then
640 echo "** Cannot --enable-pcregrep-libz because libz was not found"
641 exit 1
642 fi
643 LIBZ="-lz"
644 fi
645 AC_SUBST(LIBZ)
646
647 if test "$enable_pcregrep_libbz2" = "yes"; then
648 if test "$HAVE_BZLIB_H" != "1"; then
649 echo "** Cannot --enable-pcregrep-libbz2 because bzlib.h was not found"
650 exit 1
651 fi
652 if test "$HAVE_LIBBZ2" != "1"; then
653 echo "** Cannot --enable-pcregrep-libbz2 because libbz2 was not found"
654 exit 1
655 fi
656 LIBBZ2="-lbz2"
657 fi
658 AC_SUBST(LIBBZ2)
659
660 # Similarly for --enable-pcretest-readline
661
662 if test "$enable_pcretest_libreadline" = "yes"; then
663 if test "$HAVE_READLINE_H" != "1"; then
664 echo "** Cannot --enable-pcretest-readline because readline/readline.h was not found."
665 exit 1
666 fi
667 if test "$HAVE_HISTORY_H" != "1"; then
668 echo "** Cannot --enable-pcretest-readline because readline/history.h was not found."
669 exit 1
670 fi
671 LIBREADLINE="-lreadline"
672 fi
673 AC_SUBST(LIBREADLINE)
674
675 # Produce these files, in addition to config.h.
676 AC_CONFIG_FILES(
677 Makefile
678 libpcre.pc
679 libpcreposix.pc
680 libpcrecpp.pc
681 pcre-config
682 pcre.h
683 pcre_stringpiece.h
684 pcrecpparg.h
685 )
686
687 # Make the generated script files executable.
688 AC_CONFIG_COMMANDS([script-chmod], [chmod a+x pcre-config])
689
690 # Make sure that pcre_chartables.c is removed in case the method for
691 # creating it was changed by reconfiguration.
692 AC_CONFIG_COMMANDS([delete-old-chartables], [rm -f pcre_chartables.c])
693
694 AC_OUTPUT
695
696 # Print out a nice little message after configure is run displaying your
697 # chosen options.
698
699 cat <<EOF
700
701 $PACKAGE-$VERSION configuration summary:
702
703 Install prefix .................. : ${prefix}
704 C preprocessor .................. : ${CPP}
705 C compiler ...................... : ${CC}
706 C++ preprocessor ................ : ${CXXCPP}
707 C++ compiler .................... : ${CXX}
708 Linker .......................... : ${LD}
709 C preprocessor flags ............ : ${CPPFLAGS}
710 C compiler flags ................ : ${CFLAGS}
711 C++ compiler flags .............. : ${CXXFLAGS}
712 Linker flags .................... : ${LDFLAGS}
713 Extra libraries ................. : ${LIBS}
714
715 Build C++ library ............... : ${enable_cpp}
716 Enable UTF-8 support ............ : ${enable_utf8}
717 Unicode properties .............. : ${enable_unicode_properties}
718 Newline char/sequence ........... : ${enable_newline}
719 \R matches only ANYCRLF ......... : ${enable_bsr_anycrlf}
720 EBCDIC coding ................... : ${enable_ebcdic}
721 Rebuild char tables ............. : ${enable_rebuild_chartables}
722 Use stack recursion ............. : ${enable_stack_for_recursion}
723 POSIX mem threshold ............. : ${with_posix_malloc_threshold}
724 Internal link size .............. : ${with_link_size}
725 Match limit ..................... : ${with_match_limit}
726 Match limit recursion ........... : ${with_match_limit_recursion}
727 Build shared libs ............... : ${enable_shared}
728 Build static libs ............... : ${enable_static}
729 Link pcregrep with libz ......... : ${enable_pcregrep_libz}
730 Link pcregrep with libbz2 ....... : ${enable_pcregrep_libbz2}
731 Link pcretest with libreadline .. : ${enable_pcretest_libreadline}
732
733 EOF
734
735 dnl end configure.ac

Properties

Name Value
svn:eol-style native
svn:keywords "Author Date Id Revision Url"

webmaster@exim.org
ViewVC Help
Powered by ViewVC 1.1.12